[gentoo-commits] gentoo-x86 commit in net-misc/x2goclient: ChangeLog x2goclient-4.0.3.1.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    14/11/27 14:08:58

  Modified:             ChangeLog
  Added:                x2goclient-4.0.3.1.ebuild
  Log:
  Version bump, fixes desktop sharing
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

Revision  Changes    Path
1.34                 net-misc/x2goclient/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/x2goclient/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	22 Oct 2014 09:33:26 -0000	1.33
+++ ChangeLog	27 Nov 2014 14:08:58 -0000	1.34
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/x2goclient
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/x2goclient/ChangeLog,v 1.33 2014/10/22 09:33:26 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/x2goclient/ChangeLog,v 1.34 2014/11/27 14:08:58 voyageur Exp $
+
+*x2goclient-4.0.3.1 (27 Nov 2014)
+
+  27 Nov 2014; Bernard Cafarelli <voyageur@g.o>
+  +x2goclient-4.0.3.1.ebuild:
+  Version bump, fixes desktop sharing
 
 *x2goclient-4.0.3.0 (22 Oct 2014)
 



1.1                  net-misc/x2goclient/x2goclient-4.0.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/x2goclient-4.0.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/x2goclient/x2goclient-4.0.3.1.ebuild?rev=1.1&content-type=text/plain

Index: x2goclient-4.0.3.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/x2goclient/x2goclient-4.0.3.1.ebuild,v 1.1 2014/11/27 14:08:58 voyageur Exp $

EAPI=5
inherit eutils nsplugins qt4-r2

DESCRIPTION="The X2Go Qt client"
HOMEPAGE="http://www.x2go.org"
SRC_URI="http://code.x2go.org/releases/source/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ldap nsplugin"

DEPEND=">=net-libs/libssh-0.6.0_rc1
	net-print/cups
	dev-qt/qtcore:4[ssl]
	dev-qt/qtgui:4
	dev-qt/qtsvg:4
	ldap? ( net-nds/openldap )"
RDEPEND="${DEPEND}
	net-misc/nx"

CLIENT_BUILD=${WORKDIR}/${P}.client_build
PLUGIN_BUILD=${WORKDIR}/${P}.plugin_build

src_prepare() {
	if ! use ldap; then
		sed -e "s/-lldap//" -i x2goclient.pro || die
		sed -e "s/#define USELDAP//" -i x2goclientconfig.h || die
	fi

	mkdir -p "${CLIENT_BUILD}"
	use nsplugin && mkdir -p "${PLUGIN_BUILD}"
}

src_configure() {
	cd "${CLIENT_BUILD}"
	eqmake4 "${S}"/x2goclient.pro

	if use nsplugin;
	then
		cd "${PLUGIN_BUILD}"
		X2GO_CLIENT_TARGET=plugin eqmake4 "${S}"/x2goclient.pro
	fi
}

src_compile() {
	cd "${CLIENT_BUILD}"
	qt4-r2_src_compile

	if use nsplugin;
	then
		cd "${PLUGIN_BUILD}"
		qt4-r2_src_compile
	fi
}

src_install() {
	dobin "${CLIENT_BUILD}"/${PN}

	insinto /usr/share/pixmaps/x2goclient
	doins -r icons/*

	domenu desktop/${PN}.desktop
	doman man/man?/*

	if use nsplugin;
	then
		# PLUGINS_DIR comes from nsplugins.eclass
		exeinto /usr/$(get_libdir)/${PLUGINS_DIR}
		doexe "${PLUGIN_BUILD}"/libx2goplugin.so
	fi

	emake DESTDIR="${D}" PREFIX=/usr install_pluginprovider
}