[gentoo-commits] gentoo-x86 commit in media-video/smplayer: ChangeLog smplayer-0.6.0_rc1.ebuild

[Alexis Ballier (aballier)]

aballier    08/02/03 10:15:41

  Modified:             ChangeLog
  Added:                smplayer-0.6.0_rc1.ebuild
  Log:
  version bump
  (Portage version: 2.1.4.1)

Revision  Changes    Path
1.3                  media-video/smplayer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	1 Feb 2008 09:03:04 -0000	1.2
+++ ChangeLog	3 Feb 2008 10:15:40 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/smplayer
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.2 2008/02/01 09:03:04 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.3 2008/02/03 10:15:40 aballier Exp $
+
+*smplayer-0.6.0_rc1 (03 Feb 2008)
+
+  03 Feb 2008; Alexis Ballier <aballier@g.o>
+  +smplayer-0.6.0_rc1.ebuild:
+  version bump
 
   01 Feb 2008; Christian Faulhammer <opfer@g.o>
   smplayer-0.5.62.ebuild:



1.1                  media-video/smplayer/smplayer-0.6.0_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/smplayer-0.6.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/smplayer-0.6.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: smplayer-0.6.0_rc1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.0_rc1.ebuild,v 1.1 2008/02/03 10:15:40 aballier Exp $

inherit eutils qt4

MY_P=${P/_rc/rc}

DESCRIPTION="Great front-end for mplayer written in Qt4"
HOMEPAGE="http://smplayer.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="$(qt4_min_version 4.2)"
RDEPEND="${DEPEND}
	>media-video/mplayer-1.0_rc1"

LANGS="bg cs de en_US es fi fr hu it ja ka ko nl pl pt_BR pt_PT sk sr sv tr zh_CN zh_TW"
NOLONGLANGS="el_GR ro_RO ru_RU uk_UA"
for X in ${LANGS}; do
	IUSE="${IUSE} linguas_${X}"
done
for X in ${NOLONGLANGS}; do
	IUSE="${IUSE} linguas_${X%_*}"
done

QT4_BUILT_WITH_USE_CHECK="qt3support"

S=${WORKDIR}/${MY_P}

src_compile() {
	local MY_SVNREV="UNKNOWN"
	echo "SVN-r${MY_SVNREV}" > svn_revision.txt
	echo "#define SVN_REVISION \"SVN-r${MY_SVNREV}\"" > src/svn_revision.h

	# Fix paths in Makefile and allow parallel building
	sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
		-e "/^CONF_PREFIX=/s:\$(PREFIX)::" \
		-e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
		-e '/get_svn_revision.sh/,+2c\
	cd src && $(DEFS) $(MAKE)' \
		"${S}"/Makefile || die "sed failed"

	eqmake4 src/${PN}.pro -o src/Makefile
	emake || die "emake failed"

	# Generate translations
	cd "${S}"/src/translations
	local LANG=
	for LANG in ${LINGUAS}; do
		if has ${LANG} ${LANGS}; then
			einfo "Generating ${LANG} translation ..."
			lrelease ${PN}_${LANG}.ts || die "Failed to generate ${LANG} translation!"
			continue
		elif [[ " ${NOLONGLANGS} " == *" ${LANG}_"* ]]; then
			local X=
			for X in ${NOLONGLANGS}; do
				if [[ "${LANG}" == "${X%_*}" ]]; then
					einfo "Generating ${X} translation ..."
					lrelease ${PN}_${X}.ts || die "Failed to generate ${X} translation!"
					continue 2
				fi
			done
		fi
		ewarn "Sorry, but ${PN} does not support the ${LANG} LINGUA."
	done
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	prepalldocs
}



-- 
gentoo-commits@l.g.o mailing list