[gentoo-commits] proj/sci:master commit in: dev-python/numba/

[Andrew Ammerlaan]

commit:     c737ad5e6f3b04c9997382826ccdc15dd1380b7b
Author:     Yiyang Wu <xgreenlandforwyy <AT> gmail <DOT> com>
AuthorDate: Thu Aug  4 09:12:41 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Sun Aug  7 08:40:43 2022 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=c737ad5e

dev-python/numba: add 0.56.0

Signed-off-by: Yiyang Wu <xgreenlandforwyy <AT> gmail.com>
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/numba/numba-0.56.0.ebuild | 85 ++++++++++++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)

diff --git a/dev-python/numba/numba-0.56.0.ebuild b/dev-python/numba/numba-0.56.0.ebuild
new file mode 100644
index 000000000..15eae53a7
--- /dev/null
+++ b/dev-python/numba/numba-0.56.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit optfeature multiprocessing distutils-r1
+
+DESCRIPTION="NumPy aware dynamic Python compiler using LLVM"
+HOMEPAGE="https://numba.pydata.org/
+	https://github.com/numba"
+SRC_URI="https://github.com/numba/numba/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="openmp threads"
+
+RDEPEND="
+	>=dev-python/llvmlite-0.39.0[${PYTHON_USEDEP}]
+	<=dev-python/llvmlite-0.40.0
+	>=dev-python/numpy-1.18.0[${PYTHON_USEDEP}]
+	<dev-python/numpy-1.23[${PYTHON_USEDEP}]
+	threads? ( >=dev-cpp/tbb-2021.1 )
+"
+BDEPEND="
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/versioneer[${PYTHON_USEDEP}]
+"
+
+DISTUTILS_IN_SOURCE_BUILD=1
+distutils_enable_tests unittest
+distutils_enable_sphinx docs/source dev-python/numpydoc dev-python/sphinx_rtd_theme
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.52.0-skip_tests.patch"
+)
+
+pkg_setup() {
+	if ! use openmp; then
+		export NUMBA_DISABLE_OPENMP=1 || die
+	else
+		unset NUMBA_DISABLE_OPENMP || die
+	fi
+	if ! use threads; then
+		export NUMBA_DISABLE_TBB=1 || die
+	else
+		unset NUMBA_DISABLE_TBB || die
+		export TBBROOT="${EPREFIX}/usr" || die
+	fi
+}
+
+python_prepare_all() {
+	# This conf.py only works in a git repo
+	if use doc; then
+		git init -q || die
+		git config user.email "larry@g.o" || die
+		git config user.name "Larry the Cow" || die
+		git add . || die
+		git commit -m "init" || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	# FIXME: parallel python building fails. See Portage bug #614464 and
+	# gentoo/sci issue #1080.
+	export MAKEOPTS=-j1 || die
+	distutils-r1_python_compile
+}
+
+# https://numba.pydata.org/numba-doc/latest/developer/contributing.html?highlight=test#running-tests
+python_test() {
+	distutils_install_for_testing
+	${EPYTHON} setup.py build_ext --inplace || die \
+		"${EPYTHON} failed to build_ext"
+	${EPYTHON} runtests.py -m $(makeopts_jobs) || die \
+		"${EPYTHON} failed unittests"
+}
+
+pkg_postinst() {
+	optfeature "compile cuda code" dev-util/nvidia-cuda-sdk
+}