[gentoo-commits] gentoo-x86 commit in net-print/cups-filters: ChangeLog cups-filters-9999.ebuild cups-filters-1.0.66.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    15/03/04 17:41:31

  Modified:             ChangeLog cups-filters-9999.ebuild
  Added:                cups-filters-1.0.66.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

Revision  Changes    Path
1.137                net-print/cups-filters/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.137&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.137&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?r1=1.136&r2=1.137

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v
retrieving revision 1.136
retrieving revision 1.137
diff -u -r1.136 -r1.137
--- ChangeLog	24 Feb 2015 16:15:32 -0000	1.136
+++ ChangeLog	4 Mar 2015 17:41:31 -0000	1.137
@@ -1,6 +1,12 @@
 # ChangeLog for net-print/cups-filters
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.136 2015/02/24 16:15:32 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.137 2015/03/04 17:41:31 dilfridge Exp $
+
+*cups-filters-1.0.66 (04 Mar 2015)
+
+  04 Mar 2015; Andreas K. Huettel <dilfridge@g.o>
+  +cups-filters-1.0.66.ebuild, cups-filters-9999.ebuild:
+  Version bump
 
   24 Feb 2015; Michał Górny <mgorny@g.o> cups-filters-1.0.65.ebuild:
   Remove /usr/bin/foomatic-rip on USE=-foomatic as well.



1.54                 net-print/cups-filters/cups-filters-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?r1=1.53&r2=1.54

Index: cups-filters-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- cups-filters-9999.ebuild	14 Feb 2015 19:48:55 -0000	1.53
+++ cups-filters-9999.ebuild	4 Mar 2015 17:41:31 -0000	1.54
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.53 2015/02/14 19:48:55 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.54 2015/03/04 17:41:31 dilfridge Exp $
 
 EAPI=5
 
@@ -39,15 +39,11 @@
 	jpeg? ( virtual/jpeg:0 )
 	perl? ( dev-lang/perl:= )
 	png? ( media-libs/libpng:0= )
-	tiff? ( media-libs/tiff )
+	tiff? ( media-libs/tiff:0 )
 	zeroconf? ( net-dns/avahi[dbus] )
 "
 DEPEND="${RDEPEND}"
 
-PATCHES=(
-	"${FILESDIR}/${PN}-1.0.65-poppler0310.patch"
-)
-
 src_prepare() {
 	base_src_prepare
 	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
@@ -107,6 +103,7 @@
 
 	if ! use foomatic ; then
 		# this needs an upstream solution / configure switch
+		rm -v "${ED}/usr/bin/foomatic-rip" || die
 		rm -v "${ED}/usr/libexec/cups/filter/foomatic-rip" || die
 		rm -v "${ED}/usr/share/man/man1/foomatic-rip.1" || die
 	fi



1.1                  net-print/cups-filters/cups-filters-1.0.66.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.66.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.66.ebuild?rev=1.1&content-type=text/plain

Index: cups-filters-1.0.66.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-1.0.66.ebuild,v 1.1 2015/03/04 17:41:31 dilfridge Exp $

EAPI=5

GENTOO_DEPEND_ON_PERL=no

inherit base eutils perl-module autotools systemd

if [[ "${PV}" == "9999" ]] ; then
	inherit bzr
	EBZR_REPO_URI="http://bzr.linuxfoundation.org/openprinting/cups-filters"
	KEYWORDS=""
else
	SRC_URI="http://www.openprinting.org/download/${PN}/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~m68k-mint"
fi
DESCRIPTION="Cups PDF filters"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/openprinting/pdfasstandardprintjobformat"

LICENSE="MIT GPL-2"
SLOT="0"
IUSE="dbus +foomatic jpeg perl png static-libs tiff zeroconf"

RDEPEND="
	>=app-text/ghostscript-gpl-9.09
	app-text/poppler:=[cxx,jpeg?,lcms,tiff?,xpdf-headers(+)]
	>=app-text/qpdf-3.0.2:=
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/lcms:2
	>=net-print/cups-1.7.3
	!<=net-print/cups-1.5.9999
	sys-devel/bc
	sys-libs/zlib
	dbus? ( sys-apps/dbus )
	foomatic? ( !net-print/foomatic-filters )
	jpeg? ( virtual/jpeg:0 )
	perl? ( dev-lang/perl:= )
	png? ( media-libs/libpng:0= )
	tiff? ( media-libs/tiff:0 )
	zeroconf? ( net-dns/avahi[dbus] )
"
DEPEND="${RDEPEND}"

src_prepare() {
	base_src_prepare
	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
	eautoreconf
}

src_configure() {
	econf \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		$(use_enable dbus) \
		$(use_enable zeroconf avahi) \
		$(use_enable static-libs static) \
		--with-fontdir="fonts/conf.avail" \
		--with-pdftops=pdftops \
		--enable-imagefilters \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with tiff) \
		--with-rcdir=no \
 		--with-browseremoteprotocols=DNSSD,CUPS \
		--without-php
}

src_compile() {
	MAKEOPTS=-j1 default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_configure
		perl-module_src_compile
		popd > /dev/null
	fi
}

src_install() {
	default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_install
		perl_delete_localpod
		popd > /dev/null
	fi

	# workaround: some printer drivers still require pstoraster and pstopxl, bug #383831
	dosym /usr/libexec/cups/filter/gstoraster /usr/libexec/cups/filter/pstoraster
	dosym /usr/libexec/cups/filter/gstopxl /usr/libexec/cups/filter/pstopxl

	prune_libtool_files --all

	cp "${FILESDIR}"/cups-browsed.init.d "${T}"/cups-browsed || die

	if ! use zeroconf ; then
		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
	fi

	if ! use foomatic ; then
		# this needs an upstream solution / configure switch
		rm -v "${ED}/usr/bin/foomatic-rip" || die
		rm -v "${ED}/usr/libexec/cups/filter/foomatic-rip" || die
		rm -v "${ED}/usr/share/man/man1/foomatic-rip.1" || die
	fi

	doinitd "${T}"/cups-browsed
	systemd_dounit "${S}/utils/cups-browsed.service"
}

pkg_postinst() {
	if ! use foomatic ; then
		ewarn "You are disabling the foomatic code in cups-filters. Please do that ONLY if absolutely."
		ewarn "necessary. net-print/foomatic-filters as replacement is deprecated and unmaintained."
	fi
}