[gentoo-commits] repo/gentoo:master commit in: dev-python/joblib/

[Andrew Ammerlaan]

commit:     b9b6f16246b21c0d4dbd5bc21b2ee4991c24fba4
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Thu May 26 10:43:34 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Thu May 26 10:45:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b9b6f162

dev-python/joblib: pep517, enable py3.11

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/joblib/joblib-1.1.0-r1.ebuild | 47 ++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-python/joblib/joblib-1.1.0-r1.ebuild b/dev-python/joblib/joblib-1.1.0-r1.ebuild
new file mode 100644
index 000000000000..f627bd235c06
--- /dev/null
+++ b/dev-python/joblib/joblib-1.1.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Tools to provide lightweight pipelining in Python"
+HOMEPAGE="https://joblib.readthedocs.io/en/latest/
+	https://github.com/joblib/joblib"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/loky[${PYTHON_USEDEP}]
+"
+# joblib is imported by setup.py so we need ${RDEPEND}
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/threadpoolctl[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unbundle
+	rm -r joblib/externals || die
+	sed -e "s:'joblib.externals[^']*',\?::g" -i setup.py || die
+	find -name '*.py' -exec \
+		sed -e 's:\(joblib\)\?\.externals\.::' \
+			-e 's:from \.externals ::' \
+			-i {} + || die
+
+	# https://github.com/joblib/joblib/issues/1115
+	sed -e 's:test_parallel_call_cached_function_defined_in_jupyter:_&:' \
+		-i joblib/test/test_memory.py || die
+
+	distutils-r1_python_prepare_all
+}