[gentoo-commits] repo/gentoo:master commit in: dev-python/nbformat/

[Virgil Dupras]

commit:     1305bbf63921baf14821bf7d71e06f08cce5f4b0
Author:     Virgil Dupras <vdupras <AT> gentoo <DOT> org>
AuthorDate: Sat May  4 20:30:41 2019 +0000
Commit:     Virgil Dupras <vdupras <AT> gentoo <DOT> org>
CommitDate: Sat May  4 22:58:02 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1305bbf6

dev-python/nbformat: drop py2

Bug: https://bugs.gentoo.org/685040
Signed-off-by: Virgil Dupras <vdupras <AT> gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

 dev-python/nbformat/nbformat-4.4.0-r1.ebuild | 57 ++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-python/nbformat/nbformat-4.4.0-r1.ebuild b/dev-python/nbformat/nbformat-4.4.0-r1.ebuild
new file mode 100644
index 00000000000..854ea496fff
--- /dev/null
+++ b/dev-python/nbformat/nbformat-4.4.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE='sqlite'
+
+inherit distutils-r1
+
+DESCRIPTION="Reference implementation of the Jupyter Notebook format"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/jsonschema-2.4.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.1[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/testpath[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	pytest -vv nbformat || die
+}