[gentoo-commits] gentoo-x86 commit in media-libs/x264: x264-9999.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    11/05/28 06:30:08

  Modified:             ChangeLog
  Added:                x264-9999.ebuild
  Log:
  Import live ebuild from the multimedia overlay (requested by Nikoli).
  
  (Portage version: 2.2.0_alpha37/cvs/Linux x86_64)

Revision  Changes    Path
1.50                 media-libs/x264/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/x264/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/x264/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/x264/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/x264/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	27 Apr 2011 17:20:07 -0000	1.49
+++ ChangeLog	28 May 2011 06:30:08 -0000	1.50
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/x264
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/x264/ChangeLog,v 1.49 2011/04/27 17:20:07 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/x264/ChangeLog,v 1.50 2011/05/28 06:30:08 radhermit Exp $
+
+*x264-9999 (28 May 2011)
+
+  28 May 2011; Tim Harder <radhermit@g.o> +x264-9999.ebuild:
+  Import live ebuild from the multimedia overlay (requested by Nikoli).
 
 *x264-0.0.20110426 (27 Apr 2011)
 



1.1                  media-libs/x264/x264-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/x264/x264-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/x264/x264-9999.ebuild?rev=1.1&content-type=text/plain

Index: x264-9999.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/x264/x264-9999.ebuild,v 1.1 2011/05/28 06:30:08 radhermit Exp $

EAPI=4

if [ "${PV#9999}" != "${PV}" ] ; then
	V_ECLASS="git-2"
else
	V_ECLASS="versionator"
fi

inherit multilib toolchain-funcs ${V_ECLASS}

if [ "${PV#9999}" = "${PV}" ] ; then
	MY_P="x264-snapshot-$(get_version_component_range 3)-2245"
fi
DESCRIPTION="A free library for encoding X264/AVC streams"
HOMEPAGE="http://www.videolan.org/developers/x264.html"
if [ "${PV#9999}" != "${PV}" ] ; then
	EGIT_REPO_URI="git://git.videolan.org/x264.git"
	SRC_URI=""
else
	SRC_URI="http://ftp.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
fi

LICENSE="GPL-2"
SLOT="0"
if [ "${PV#9999}" != "${PV}" ] ; then
	KEYWORDS=""
else
	KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
fi
IUSE="debug +threads pic static-libs"

RDEPEND=""
ASM_DEP=">=dev-lang/yasm-0.6.2"
DEPEND="
	amd64? ( ${ASM_DEP} )
	x86? ( ${ASM_DEP} )
	x86-fbsd? ( ${ASM_DEP} )
"
if [ "${PV#9999}" = "${PV}" ] ; then
	S=${WORKDIR}/${MY_P}
fi
DOCS="AUTHORS doc/*.txt"

src_configure() {
	tc-export CC

	local myconf=""
	use debug && myconf+=" --enable-debug"
	use static-libs && myconf+=" --enable-static"
	use threads || myconf+=" --disable-thread"

	if use x86 && use pic; then
		myconf+=" --disable-asm"
	fi

	./configure \
		--prefix="${EPREFIX}"/usr \
		--libdir="${EPREFIX}"/usr/$(get_libdir) \
		--disable-cli \
		--disable-avs \
		--disable-lavf \
		--disable-swscale \
		--disable-ffms \
		--disable-gpac \
		--enable-pic \
		--enable-shared \
		--extra-asflags="${ASFLAGS}" \
		--extra-cflags="${CFLAGS}" \
		--extra-ldflags="${LDFLAGS}" \
		--host="${CHOST}" \
		${myconf} \
		|| die
}