[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-shell-extension-gsconnect/

[Pacho Ramos]

commit:     41afbe2947ec456d11aae071737ff561ad8ccce6
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 14 20:57:20 2019 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Sep 14 21:00:56 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41afbe29

gnome-extra/gnome-shell-extension-gsconnect: Bump to v26

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../gnome-shell-extension-gsconnect/Manifest       |  1 +
 .../gnome-shell-extension-gsconnect-26.ebuild      | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/Manifest b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
index 6c4cd16d014..71ca9ed2084 100644
--- a/gnome-extra/gnome-shell-extension-gsconnect/Manifest
+++ b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
@@ -1 +1,2 @@
 DIST gnome-shell-extension-gsconnect-24.tar.gz 287521 BLAKE2B 5cf8d3c932c8746a5fd66003233cb83adf71d637199947c01a59e965c60eecb41f5b037d949930753d12ebdbb964b3ff6ae6e05809a6de52e941307c8a659ea2 SHA512 b2ae669dae0d3c8ef4d28ad186a1d61706c005c5e87d58565d6d1544f97d5ca46ee230e60ddd986ee17a6edb411976cdbbb5226b678e6eb097b08afd1b0160c7
+DIST gnome-shell-extension-gsconnect-26.tar.gz 303823 BLAKE2B 7fd112c032d717e87c7189a5f06b97a246216fa1895bb3d837c8b53c3312eed9a6999c20db3e98112cdacc309d56021920b78ebb387c55335fba1965b86c117f SHA512 c32469bf9c1b3903979b1e354d6c214807158f35d4824b60597639084064d23d194bda91a3a1cd5a99d7fdaf2bea48ad7f4c9aad3befb55e59694d195b7d8a9a

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-26.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-26.ebuild
new file mode 100644
index 00000000000..42904739987
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-26.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils meson readme.gentoo-r1
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/andyholmes/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/andyholmes/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nautilus"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.48
+	>=gnome-base/gnome-shell-3.28
+	gnome-base/gvfs
+	|| ( ( net-libs/gnome-online-accounts dev-libs/libgdata ) dev-libs/folks )
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	>=dev-util/meson-0.49.0
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	meson_src_configure \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}