[gentoo-commits] repo/gentoo:master commit in: dev-python/astroid/

[Patrick McLean]

commit:     220ea6de926edca2673a378b941f7b5e6883bf6e
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 11 02:13:44 2020 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Wed Mar 11 02:14:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=220ea6de

dev-python/astroid-2.3.3-r2: revbump, don't lock wrapt dep

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 dev-python/astroid/astroid-2.3.3-r2.ebuild | 56 ++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-python/astroid/astroid-2.3.3-r2.ebuild b/dev-python/astroid/astroid-2.3.3-r2.ebuild
new file mode 100644
index 00000000000..528031d8ee8
--- /dev/null
+++ b/dev-python/astroid/astroid-2.3.3-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="https://github.com/PyCQA/astroid https://pypi.org/project/astroid/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.11.2[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.3.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.3.3-no-pytest-runner.patch"
+)
+
+python_prepare_all() {
+	# Disable failing tests
+
+	# no idea why this test fails
+	sed -i -e "s/test_knownValues_get_builtin_module_part/_&/" \
+		astroid/tests/unittest_modutils.py || die
+
+	sed -r -e 's:"wrapt(~|=)=.+":"wrapt":' \
+		-i astroid/__pkginfo__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" -m pytest -v --pyargs astroid/tests \
+		|| die "tests failed with ${EPYTHON}"
+}