[gentoo-commits] gentoo-x86 commit in app-arch/rar: rar-4.2.0.ebuild ChangeLog rar-4.2.0_beta3.ebuild

[Jeff Horelick (jdhore)]

jdhore      12/07/10 08:44:37

  Modified:             ChangeLog
  Added:                rar-4.2.0.ebuild
  Removed:              rar-4.2.0_beta3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha116/cvs/Linux i686)

Revision  Changes    Path
1.83                 app-arch/rar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	2 Jun 2012 22:12:10 -0000	1.82
+++ ChangeLog	10 Jul 2012 08:44:37 -0000	1.83
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/rar
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v 1.82 2012/06/02 22:12:10 serkan Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v 1.83 2012/07/10 08:44:37 jdhore Exp $
+
+*rar-4.2.0 (10 Jul 2012)
+
+  10 Jul 2012; Jeff Horelick <jdhore@g.o> +rar-4.2.0.ebuild,
+  -rar-4.2.0_beta3.ebuild:
+  Version bump.
 
 *rar-4.2.0_beta3 (02 Jun 2012)
 



1.1                  app-arch/rar/rar-4.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/rar-4.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/rar-4.2.0.ebuild?rev=1.1&content-type=text/plain

Index: rar-4.2.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/rar-4.2.0.ebuild,v 1.1 2012/07/10 08:44:37 jdhore Exp $
EAPI=4

DESCRIPTION="RAR compressor/uncompressor"
HOMEPAGE="http://www.rarsoft.com/"
URI_x86="http://www.rarlab.com/rar/rarlinux-${PV}.tar.gz"
URI_amd64="http://www.rarlab.com/rar/rarlinux-x64-${PV}.tar.gz"
URI_w64="http://www.rarlab.com/rar/winrar-x64-${PV//.}.exe"
SRC_URI="x86? ( ${URI_x86} )
	amd64? ( ${URI_amd64} )
	all_sfx? (
		${URI_x86}
		${URI_amd64}
		${URI_w64}
	)"

LICENSE="RAR"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="all_sfx static"

DEPEND="all_sfx? ( app-arch/unrar )"
RDEPEND="sys-libs/glibc"

S=${WORKDIR}/${PN}

QA_DT_HASH="opt/rar/default.sfx
	opt/rar/default-elf32.sfx
	opt/rar/default-elf64.sfx
	opt/rar/default-win32.sfx
	opt/rar/default-win64.sfx
	opt/rar/WinCon.SFX
	opt/rar/WinCon64.SFX
	opt/rar/Zip.SFX
	opt/rar/Zip64.SFX
	opt/rar/unrar
	opt/rar/rar"
QA_PRESTRIPPED=${QA_DT_HASH}

src_unpack() {
	use x86 && unpack ${URI_x86##*/}
	use amd64 && unpack ${URI_amd64##*/}
	rm -f "${S}"/license.txt
	if use all_sfx ; then
		mkdir sfx
		cd sfx
		unpack ${URI_x86##*/}
		mv rar/default.sfx default-elf32.sfx || die
		unpack ${URI_amd64##*/}
		mv rar/default.sfx default-elf64.sfx || die
		ln -s "${DISTDIR}"/${URI_w64##*/} w64.rar
		unpack ./w64.rar
		mv Default.SFX default-win32.sfx || die
		mv Default64.SFX default-win64.sfx || die
	fi
}

src_compile() { :; }

src_install() {
	exeinto /opt/rar
	doexe rar unrar || die
	use static && { newexe rar_static rar || die ; }

	dodir /opt/bin
	dosym ../rar/rar /opt/bin/rar || die
	dosym ../rar/unrar /opt/bin/unrar || die

	insinto /opt/rar
	if use all_sfx ; then
		doins "${WORKDIR}"/sfx/*.{sfx,SFX} || die
	else
		doins default.sfx || die
	fi
	doins rarfiles.lst || die
	dodoc *.txt
}