[gentoo-commits] gentoo-x86 commit in dev-cpp/commoncpp2: ChangeLog commoncpp2-1.8.0.ebuild

[Peter Volkov (pva)]

pva         10/04/23 10:17:57

  Modified:             ChangeLog
  Added:                commoncpp2-1.8.0.ebuild
  Log:
  Version bump, bug #279505, thank Eric Womer for report. This should fix gcc-4.4 build issues.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.50                 dev-cpp/commoncpp2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/commoncpp2/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/commoncpp2/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/commoncpp2/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-cpp/commoncpp2/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	30 Jul 2009 07:58:34 -0000	1.49
+++ ChangeLog	23 Apr 2010 10:17:57 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for dev-cpp/commoncpp2
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/commoncpp2/ChangeLog,v 1.49 2009/07/30 07:58:34 dirtyepic Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/commoncpp2/ChangeLog,v 1.50 2010/04/23 10:17:57 pva Exp $
+
+*commoncpp2-1.8.0 (23 Apr 2010)
+
+  23 Apr 2010; Peter Volkov <pva@g.o> +commoncpp2-1.8.0.ebuild:
+  Version bump, bug #279505, thank Eric Womer for report. This should fix
+  gcc-4.4 build issues.
 
   30 Jul 2009; Ryan Hill <dirtyepic@g.o> commoncpp2-1.6.3.ebuild,
   +files/commoncpp2-1.6.3-glibc-2.10.patch:



1.1                  dev-cpp/commoncpp2/commoncpp2-1.8.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/commoncpp2/commoncpp2-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/commoncpp2/commoncpp2-1.8.0.ebuild?rev=1.1&content-type=text/plain

Index: commoncpp2-1.8.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/commoncpp2/commoncpp2-1.8.0.ebuild,v 1.1 2010/04/23 10:17:57 pva Exp $

EAPI="2"
inherit eutils autotools

DESCRIPTION="GNU Common C++ is a C++ framework offering portable support for threading, sockets, file access, daemons, persistence, serial I/O, XML parsing, and system services"
SRC_URI="mirror://gnu/commoncpp/${P}.tar.gz"
HOMEPAGE="http://www.gnu.org/software/commoncpp/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug doc examples ipv6 gnutls"

RDEPEND="gnutls? ( dev-libs/libgcrypt
		net-libs/gnutls )
	!gnutls? ( dev-libs/openssl )
	sys-libs/zlib"
DEPEND="doc? ( >=app-doc/doxygen-1.3.6 )
	${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}/1.6.1-gcc42_atomicity.patch"
	epatch "${FILESDIR}/1.6.2-configure_detect_netfilter.patch" # bug 236177
	eautoreconf
}

src_configure() {
	use doc || \
		sed -i "s/^DOXYGEN=.*/DOXYGEN=no/" configure || die "sed failed"

	local myconf
	if use gnutls; then
		myconf="--with-gnutls --without-openssl"
	else
		myconf="--without-gnutls --with-openssl"
	fi

	econf \
		$(use_enable debug) \
		$(use_with ipv6 ) \
		${myconf}
}

src_compile() {
	emake -j1 || die "emake failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS NEWS ChangeLog README THANKS TODO COPYING.addendum

	# Only install html docs
	# man and latex available, but seems a little wasteful
	use doc && dohtml doc/html/*

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		cd demo
		doins *.cpp *.h *.xml README
	fi
}

pkg_postinst() {
	ewarn "There's a change in the ABI between version 1.5.x and 1.6.x, please"
	ewarn "run the following command to find broken packages and rebuild them:"
	ewarn "    revdep-rebuild --library=libccext2-1.5.so"
}

# Some of the tests hang forever
#src_test() {
#	cd "${S}/tests"
#	emake || die "emake tests failed"
#	./test.sh || die "tests failed"
#}