[gentoo-commits] repo/gentoo:master commit in: dev-python/zope-interface/

[Michał Górny]

commit:     d437b94af2b8c4fc78530e2dfc5189e6c025527e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  9 14:55:23 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr  9 14:58:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d437b94a

dev-python/zope-interface: EAPI 8, PEP517, namespace retirement

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../zope-interface/zope-interface-5.4.0-r1.ebuild  | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild b/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild
new file mode 100644
index 000000000000..e1ec0460269b
--- /dev/null
+++ b/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Interfaces for Python"
+HOMEPAGE="https://pypi.org/project/zope.interface/ https://github.com/zopefoundation/zope.interface"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+BDEPEND="
+	test? (
+		dev-python/zope-event[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/5.1.0-drop-coverage.patch
+)
+
+distutils_enable_tests unittest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	# this is needed to keep the tests working while
+	# dev-python/namespace-zope is still installed
+	cat > zope/__init__.py <<-EOF || die
+		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
+	EOF
+	eunittest
+	rm zope/__init__.py || die
+}