[gentoo-commits] gentoo-x86 commit in dev-lang/qu-prolog: ChangeLog qu-prolog-8.6.ebuild

[Keri Harris (keri)]

keri        08/07/30 08:22:59

  Modified:             ChangeLog
  Added:                qu-prolog-8.6.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.5.5)

Revision  Changes    Path
1.46                 dev-lang/qu-prolog/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	2 Jul 2008 07:24:25 -0000	1.45
+++ ChangeLog	30 Jul 2008 08:22:59 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/qu-prolog
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v 1.45 2008/07/02 07:24:25 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v 1.46 2008/07/30 08:22:59 keri Exp $
+
+*qu-prolog-8.6 (30 Jul 2008)
+
+  30 Jul 2008; keri <keri@g.o> +files/qu-prolog-8.6-portage.patch,
+  +qu-prolog-8.6.ebuild:
+  Version bump.
 
 *qu-prolog-8.5 (02 Jul 2008)
 



1.1                  dev-lang/qu-prolog/qu-prolog-8.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/qu-prolog-8.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/qu-prolog-8.6.ebuild?rev=1.1&content-type=text/plain

Index: qu-prolog-8.6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/qu-prolog-8.6.ebuild,v 1.1 2008/07/30 08:22:59 keri Exp $

EAPI=1

inherit eutils

MY_P=qp${PV}

DESCRIPTION="Qu-Prolog is an extended Prolog supporting quantifiers, object-variables and substitutions"
HOMEPAGE="http://www.itee.uq.edu.au/~pjr/HomePages/QuPrologHome.html"
SRC_URI="http://www.itee.uq.edu.au/~pjr/HomePages/QPFiles/${MY_P}.tar.gz"
#	qt4? ( mirror://gentoo/${P}-xqp-qt4.tar.gz )"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~ppc ~sparc ~x86"
IUSE="debug doc examples qt4 threads"

DEPEND="dev-lang/perl
	qt4? ( || ( x11-libs/qt-gui:4 >=x11-libs/qt-4.1.0:4 ) )"

S="${WORKDIR}"/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-portage.patch
}

src_compile() {
	econf \
		$(use_enable debug) \
		$(use_enable threads multiple-threads) \
		|| die "econf failed"
	emake || die "emake failed"

	if use qt4; then
		cd "${S}"/src/xqp
		qmake || die "qmake xqp failed"
		emake || die "emake xqp failed"
	fi
}

src_install() {
	exeinto /usr/bin
	doexe bin/qa bin/qdeal bin/qem bin/ql
	doexe bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp bin/qppp
	doexe bin/kq

	if use qt4; then
		doexe src/xqp/xqp
	fi

	insinto /usr/$(get_libdir)/${PN}/bin
	doins prolog/qc1/qc1.qx \
		prolog/qecat/qecat.qx \
		prolog/qg/qg.qx \
		prolog/qp/qp.qx

	insinto /usr/$(get_libdir)/${PN}/library
	doins prolog/library/*.qo

	insinto /usr/$(get_libdir)/${PN}/compiler
	doins prolog/compiler/*.qo

	doman doc/man/man1/*.1

	dodoc README

	if use doc ; then
		docinto reference-manual
		dodoc doc/manual/*.html
		docinto user-guide
		dodoc doc/user/main.ps
	fi

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.ql
		docinto examples
		dodoc examples/README
	fi
}