[gentoo-commits] repo/gentoo:master commit in: x11-themes/gtk-engines-ubuntulooks/, x11-themes/gtk-engines-ubuntulooks/files/

[David Seifert]

commit:     09934c9619f46b4546b5c6765521e426184c8ecf
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 24 11:53:18 2019 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Tue Dec 24 11:53:18 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=09934c96

x11-themes/gtk-engines-ubuntulooks: Port to EAPI 7

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 .../gtk-engines-ubuntulooks-0.9.12-glib-2.31.patch |  4 +--
 .../gtk-engines-ubuntulooks-0.9.12-r3.ebuild       | 40 ++++++++++++++--------
 2 files changed, 27 insertions(+), 17 deletions(-)

diff --git a/x11-themes/gtk-engines-ubuntulooks/files/gtk-engines-ubuntulooks-0.9.12-glib-2.31.patch b/x11-themes/gtk-engines-ubuntulooks/files/gtk-engines-ubuntulooks-0.9.12-glib-2.31.patch
index 453407f14ee..8629ebb63ff 100644
--- a/x11-themes/gtk-engines-ubuntulooks/files/gtk-engines-ubuntulooks-0.9.12-glib-2.31.patch
+++ b/x11-themes/gtk-engines-ubuntulooks/files/gtk-engines-ubuntulooks-0.9.12-glib-2.31.patch
@@ -1,7 +1,7 @@
 http://bugs.gentoo.org/419395
 
---- engine/src/animation.c
-+++ engine/src/animation.c
+--- a/engine/src/animation.c
++++ b/engine/src/animation.c
 @@ -7,7 +7,7 @@
  #include "animation.h"
  

diff --git a/x11-themes/gtk-engines-ubuntulooks/gtk-engines-ubuntulooks-0.9.12-r3.ebuild b/x11-themes/gtk-engines-ubuntulooks/gtk-engines-ubuntulooks-0.9.12-r3.ebuild
index 94c86304a7f..7ac97c44e10 100644
--- a/x11-themes/gtk-engines-ubuntulooks/gtk-engines-ubuntulooks-0.9.12-r3.ebuild
+++ b/x11-themes/gtk-engines-ubuntulooks/gtk-engines-ubuntulooks-0.9.12-r3.ebuild
@@ -1,34 +1,43 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
-inherit autotools eutils
+EAPI=7
+
+inherit autotools
 
 PATCH_LEVEL=12
 MY_PN=${PN/gtk-engines-}
 
 DESCRIPTION="A derivative of the standard Clearlooks GTK+ 2.x engine with more orange feel"
 HOMEPAGE="http://packages.ubuntu.com/search?keywords=gtk2-engines-ubuntulooks"
-SRC_URI="mirror://ubuntu/pool/main/u/${MY_PN}/${MY_PN}_${PV}.orig.tar.gz
+SRC_URI="
+	mirror://ubuntu/pool/main/u/${MY_PN}/${MY_PN}_${PV}.orig.tar.gz
 	mirror://ubuntu/pool/main/u/${MY_PN}/${MY_PN}_${PV}-${PATCH_LEVEL}.diff.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ~ppc x86 ~amd64-linux ~x86-linux ~x86-macos"
-IUSE=""
 
-RDEPEND=">=dev-libs/glib-2
+RDEPEND="
+	dev-libs/glib:2
 	x11-libs/gtk+:2"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
 S=${WORKDIR}/${MY_PN}-${PV}
 
-src_prepare() {
-	epatch "${WORKDIR}"/${MY_PN}_${PV}-${PATCH_LEVEL}.diff
-	EPATCH_FORCE=yes EPATCH_SUFFIX=patch epatch debian/patches
-	epatch "${FILESDIR}"/${P}-glib-2.31.patch #419395
+PATCHES=(
+	"${WORKDIR}"/${MY_PN}_${PV}-${PATCH_LEVEL}.diff
+	"${S}"/debian/patches/01_fix_listview_arrows_drawing.patch
+	"${S}"/debian/patches/01_fix_tick_box_drawing.patch
+	"${S}"/debian/patches/01_progressbar-fix.patch
+	"${S}"/debian/patches/02_fix-firefox-buttons.patch
+	# https://bugs.gentoo.org/419395
+	"${FILESDIR}"/${P}-glib-2.31.patch
+)
 
+src_prepare() {
+	default
 	eautoreconf # update libtool for interix
 }
 
@@ -37,8 +46,9 @@ src_configure() {
 }
 
 src_install() {
-	emake DESTDIR="${D}" install
-	dodoc AUTHORS ChangeLog README
+	default
 	newdoc debian/changelog ChangeLog.debian
-	find "${ED}"/usr -name '*.la' -type f -exec rm -f {} +
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
 }