[gentoo-commits] gentoo-x86 commit in games-fps/alienarena: ChangeLog alienarena-20100726.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/07/30 16:59:54

  Modified:             ChangeLog
  Added:                alienarena-20100726.ebuild
  Log:
  version bump
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.25                 games-fps/alienarena/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/alienarena/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/alienarena/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/alienarena/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	11 Jul 2010 12:26:57 -0000	1.24
+++ ChangeLog	30 Jul 2010 16:59:54 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for games-fps/alienarena
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.24 2010/07/11 12:26:57 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.25 2010/07/30 16:59:54 mr_bones_ Exp $
+
+*alienarena-20100726 (30 Jul 2010)
+
+  30 Jul 2010; Michael Sterrett <mr_bones_@g.o>
+  +alienarena-20100726.ebuild:
+  version bump
 
   11 Jul 2010; Christian Faulhammer <fauli@g.o>
   alienarena-20100504.ebuild:



1.1                  games-fps/alienarena/alienarena-20100726.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/alienarena/alienarena-20100726.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/alienarena/alienarena-20100726.ebuild?rev=1.1&content-type=text/plain

Index: alienarena-20100726.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/alienarena-20100726.ebuild,v 1.1 2010/07/30 16:59:54 mr_bones_ Exp $

EAPI=2
inherit eutils games

MY_PN=alienarena7_45
DESCRIPTION="Fast-paced multiplayer deathmatch game"
HOMEPAGE="http://red.planetarena.org/"
SRC_URI="http://icculus.org/alienarena/Files/${MY_PN}-Linux${PV}.zip"

LICENSE="GPL-2 free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated opengl"

UIRDEPEND="media-libs/jpeg
	media-libs/openal
	media-libs/libvorbis
	virtual/glu
	virtual/opengl
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm"
RDEPEND="opengl? ( ${UIRDEPEND} )
	!opengl? ( !dedicated? ( ${UIRDEPEND} ) )
	net-misc/curl"
UIDEPEND="x11-proto/xf86dgaproto
	x11-proto/xf86vidmodeproto"
DEPEND="${RDEPEND}
	opengl? ( ${UIDEPEND} )
	!opengl? ( !dedicated? ( ${UIDEPEND} ) )
	dev-util/pkgconfig
	app-arch/unzip"

S=${WORKDIR}/${MY_PN}/source

src_prepare() {
	rm -f ../*/*.so
	sed -i \
		-e 's:\($(SHLIBLDFLAGS)\):$(LDFLAGS) \1:' \
		Makefile \
		|| die "sed failed"
}

src_compile() {
	emake \
		ARCH="unknown" \
		OSTYPE="linux" \
		OPTIMIZED_CFLAGS=no \
		WITH_DATADIR=yes \
		WITH_LIBDIR=yes \
		DATADIR="${GAMES_DATADIR}"/${PN} \
		LIBDIR="$(games_get_libdir)"/${PN} \
		$(use opengl && ! use dedicated && echo BUILD=CLIENT) \
		$(! use opengl && use dedicated && echo BUILD=DEDICATED) \
		$(use opengl && use dedicated && echo BUILD=ALL) \
		$(use opengl || use dedicated || echo BUILD=CLIENT) \
		|| die "emake failed"
}

src_install() {
	cd release
	exeinto "$(games_get_libdir)"/${PN}
	doexe game.so || die "doexe failed"
	dosym . "$(games_get_libdir)"/${PN}/arena
	dosym . "$(games_get_libdir)"/${PN}/data1

	if use opengl || ! use dedicated ; then
		newgamesbin crx ${PN} || die "newgamesbin crx failed"
		make_desktop_entry ${PN} "Alien Arena"
	fi

	if use dedicated ; then
		newgamesbin crded ${PN}-ded || die "newgamesbin crded failed"
	fi

	cd "${WORKDIR}"/${MY_PN}
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r arena botinfo data1 || die "doins failed"
	newicon aa.png ${PN}.png || die "newicon failed"
	dodoc docs/README.txt

	prepgamesdirs
}