[gentoo-commits] repo/gentoo:master commit in: gnome-extra/nemo/

[Sam James]

commit:     b46e841f00b4d4310445bd674f13270aff9e2485
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Wed Jul 29 16:00:28 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Sep  9 02:15:00 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b46e841f

gnome-extra/nemo: 4.6.5 version bump

Tracker support restored upstream.

Bug: https://bugs.gentoo.org/733544
Closes: https://bugs.gentoo.org/709298
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/nemo/Manifest          |  1 +
 gnome-extra/nemo/metadata.xml      |  3 ++
 gnome-extra/nemo/nemo-4.6.5.ebuild | 84 ++++++++++++++++++++++++++++++++++++++
 3 files changed, 88 insertions(+)

diff --git a/gnome-extra/nemo/Manifest b/gnome-extra/nemo/Manifest
index 0b54e7a9306..bbffdebbe95 100644
--- a/gnome-extra/nemo/Manifest
+++ b/gnome-extra/nemo/Manifest
@@ -1 +1,2 @@
 DIST nemo-4.4.2.tar.gz 1462269 BLAKE2B 365cd98a05c0c4aa1c86a3e7a565904852bd02d92ace8593043ae8a58f5b9d3eda71e8b0d329a177ed59c0d8f1330ae61f5bcc6671110e82bbd9baad84faa9f0 SHA512 b951c401f93d04061a0ef0accc810ecc7f0487617f089960ab58886a6ca6ecd0af3a98c47e9a620a4d6f8f530a11af9cae20903d089177e69bfa12f9ca31ec5c
+DIST nemo-4.6.5.tar.gz 1468701 BLAKE2B 42b47300782745e4ae98db164ca547b0794caf8f0883db4241f2f0ed2e375e5c8564cff6d878142b55744ce41f49c60aad3f24930398ff68444e32c572d7e9bd SHA512 3c8c95e75e8bc499b56d1fd133f5ccc86ad18dae2219772b732586fd684a4a7a36e51fa61e6b734ad182ffd96636bdf276b8645d049e5ca68795fac274236eb6

diff --git a/gnome-extra/nemo/metadata.xml b/gnome-extra/nemo/metadata.xml
index 531825b14a6..883e47a87f0 100644
--- a/gnome-extra/nemo/metadata.xml
+++ b/gnome-extra/nemo/metadata.xml
@@ -16,4 +16,7 @@
 	<upstream>
 		<remote-id type="github">linuxmint/nemo</remote-id>
 	</upstream>
+	<use>
+		<flag name="tracker">Add support for <pkg>app-misc/tracker</pkg> search</flag>
+	</use>
 </pkgmetadata>

diff --git a/gnome-extra/nemo/nemo-4.6.5.ebuild b/gnome-extra/nemo/nemo-4.6.5.ebuild
new file mode 100644
index 00000000000..e64955da835
--- /dev/null
+++ b/gnome-extra/nemo/nemo-4.6.5.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson gnome2-utils python-single-r1 virtualx xdg
+
+DESCRIPTION="A file manager for Cinnamon, forked from Nautilus"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/"
+SRC_URI="https://github.com/linuxmint/nemo/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc exif +nls selinux tracker xmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT=test
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.37.3:2[dbus]
+	>=dev-libs/gobject-introspection-0.6.4:=
+	>=gnome-extra/cinnamon-desktop-4.4:0=
+	>=x11-libs/pango-1.28.3
+	>=x11-libs/gtk+-3.9.10:3[introspection]
+	>=dev-libs/libxml2-2.7.8:2
+
+	gnome-base/dconf:0=
+	>=x11-libs/libnotify-0.7:=
+	x11-libs/libX11
+	>=x11-libs/xapps-1.4.0
+
+	exif? ( >=media-libs/libexif-0.6.20:= )
+	tracker? ( >=app-misc/tracker-2.0:= )
+	xmp? ( >=media-libs/exempi-2.2.0:= )
+	selinux? ( sys-libs/libselinux )
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+	nls? ( >=gnome-extra/cinnamon-translations-4.4 )
+	$(python_gen_cond_dep '
+		dev-python/polib[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+"
+PDEPEND=">=gnome-base/gvfs-0.1.2"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.31.0
+	>=dev-util/intltool-0.40.1
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	xdg_environment_reset
+	default
+	python_fix_shebang files/usr/share/nemo/actions
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif)
+		$(meson_use tracker)
+		$(meson_use xmp)
+		$(meson_use selinux)
+		$(meson_use doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}