[gentoo-commits] gentoo-x86 commit in net-libs/gupnp: gupnp-0.20.11.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/31 10:05:41

  Modified:             ChangeLog
  Added:                gupnp-0.20.11.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.83                 net-libs/gupnp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	26 Apr 2014 06:36:11 -0000	1.82
+++ ChangeLog	31 May 2014 10:05:41 -0000	1.83
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gupnp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v 1.82 2014/04/26 06:36:11 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v 1.83 2014/05/31 10:05:41 pacho Exp $
+
+*gupnp-0.20.11 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@g.o> +gupnp-0.20.11.ebuild:
+  Version bump
 
   26 Apr 2014; Pacho Ramos <pacho@g.o> -gupnp-0.18.4.ebuild,
   -gupnp-0.20.8.ebuild:



1.1                  net-libs/gupnp/gupnp-0.20.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/gupnp-0.20.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/gupnp-0.20.11.ebuild?rev=1.1&content-type=text/plain

Index: gupnp-0.20.11.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/gupnp-0.20.11.ebuild,v 1.1 2014/05/31 10:05:41 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
VALA_MIN_API_VERSION="0.14"
VALA_USE_DEPEND="vapigen"
# FIXME: Claims to works with python3 but appears to be wishful thinking
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="xml"

inherit gnome2 python-r1 vala

DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"

LICENSE="LGPL-2"
SLOT="0/4"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="connman +introspection kernel_linux networkmanager"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="
	${PYTHON_DEPS}
	>=net-libs/gssdp-0.13.0:0=[introspection?]
	>=net-libs/libsoup-2.28.2:2.4[introspection?]
	>=dev-libs/glib-2.24:2
	dev-libs/libxml2
	|| (
		>=sys-apps/util-linux-2.16
		<sys-libs/e2fsprogs-libs-1.41.8 )
	introspection? (
			>=dev-libs/gobject-introspection-0.6.4
			$(vala_depend) )
	connman? (
		>=dev-libs/glib-2.28:2
		>=net-misc/connman-0.80 )
	networkmanager? ( >=dev-libs/glib-2.26:2 )
	!net-libs/gupnp-vala
"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1
	sys-devel/gettext
	virtual/pkgconfig
"

src_prepare() {
	use introspection && vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	local backend=unix
	use kernel_linux && backend=linux
	use connman && backend=connman
	use networkmanager && backend=network-manager

	gnome2_src_configure \
		$(use_enable introspection) \
		--disable-static \
		--with-context-manager=${backend}
}

src_install() {
	gnome2_src_install
	python_parallel_foreach_impl python_doscript tools/gupnp-binding-tool
}