[gentoo-commits] repo/gentoo:master commit in: net-fs/samba/

[Ian Stakenvicius]

commit:     fa5b1182216f8eb4784c4c5eaa3db5d6c01844f8
Author:     Ian Stakenvicius <axs <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 10 17:18:28 2017 +0000
Commit:     Ian Stakenvicius <axs <AT> gentoo <DOT> org>
CommitDate: Thu Aug 10 17:20:59 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa5b1182

net-fs/samba: bump 4.6 to v4.6.7

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 net-fs/samba/Manifest           |   2 +
 net-fs/samba/samba-4.6.7.ebuild | 299 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 301 insertions(+)

diff --git a/net-fs/samba/Manifest b/net-fs/samba/Manifest
index 51b0fa36cee..5ab51c9735d 100644
--- a/net-fs/samba/Manifest
+++ b/net-fs/samba/Manifest
@@ -4,5 +4,7 @@ DIST samba-4.5.11-disable-python-patches.tar.xz 6292 SHA256 8db451910c3d46fc7152
 DIST samba-4.5.12.tar.gz 21011562 SHA256 f4c17123e3cc852a5ecc7e38884b00deab57632b9519aebc243e2a94b9b5ace4 SHA512 797ef6b1aebd7122f4630e3a591301162d3b3bdab70509ed78aca71a321d53c635164bbfb192922d19245b45e6333ff132e89fc35954f56e33970af4cc5bd604 WHIRLPOOL e7f58275f514652678f760446b5a9a3646e008657bedcacdbee7a625d011abc99c8cc04f04109df0e2b38253f9020387376ec84f233c9ac25554c96499a4fa4b
 DIST samba-4.6.0-disable-python-patches.tar.xz 7544 SHA256 508adeea65604ef8f4da006504de7c27bed56d7003db1166dc5d3b01f5a6be6e SHA512 07de2c0877aff31069ed0ab4fbe1c2272c854ae898ee5300a3b176ba31a218b05acff0b5120a5da0995592e7877c607865d2194c992df17b27c993836f58a654 WHIRLPOOL 12888f2ebf8d4ed5619860b2e6929599022b8ab1245970a5e1258f26e89aca1f87ab58fa54c7300dbd79a0c8fd6955e12c8aca6eeca246cdf06661d53ca3f6dd
 DIST samba-4.6.6.tar.gz 21120791 SHA256 fc31c809f7d85ae30f2b7dcddcb8404201b626047458cb5f2b743d4f6f3f1a8e SHA512 e06bdc83f44c449212f2e45a902e2ca547505a75e970166259b91d2093fb442cdfd456e724d0e842b674b4b8d5bdbe9072996d768c08ebd979a44b2494a59799 WHIRLPOOL eee4bc7e6d5a102b4ab7146354afd7501bc4ad6a3af1aa63ffecf7eb54dc04f113248048157ca9e8c9cd3c21a0931b0fae1d8dc7232e29a92ebbf5d6cccd4c55
+DIST samba-4.6.7-disable-python-patches.tar.xz 8896 SHA256 33702adba80e9886625fda8cba46d4017ae603f5d9cf9d3dc78e5ef30ff6f5eb SHA512 c45e548a49735e17b568bebf07dc7409de3de0f93256d1dcf345d2723a27d22a51d860ed921785354fda691f83be4eca3b9d618d5c332438ebf97518a01983eb WHIRLPOOL 1cb176480b8583369e1085c8e122958112c0d13aa8ba78cd57dfd04b17c7d8f0a0664a43d277deba86775f1944eab052f4fb9459f64506215ae25184c86cbe40
+DIST samba-4.6.7.tar.gz 21137329 SHA256 9ef24393de08390f236cabccd6a420b5cea304e959cbf1a99ff317325db3ddfa SHA512 394c28204bae4134e6a9d2e5b8f087a425dc4ac4ceecd8b29315acff1a92349d40ef0b6a9cc34f5ad18ff5ec9979199837c87f687858cb4e6687968284303aa5 WHIRLPOOL 14282c4a88a22f932099ef47dc50f57c5fef87d6909d529d3eb837b6e958f490a5fd64ce1a5dfdd36eab5ac82b41583736953be2be279f70f0491c61fd1d0d92
 DIST samba-disable-python-patches-4.2.12.tar.xz 6052 SHA256 8903eacbabdfaf7b64cbde03d7c367d1efdc92e54090f0f4b9ed5d2a462b1c18 SHA512 c527d0a052d3211e5b12c17bc94db56cc5e5545189ed65a760c0656c94c22e27a4b159e6439eb0370873e1619873a741f3b3bd10d3876b38eb3914a87eace372 WHIRLPOOL ad63db55d5dc96f56e6c9b30c2092e2f6e206b0ed5d13c249879d10753c8db2f475c5d4e651e2fc042ad992b648d3b4465f1b28c6b4bbf821cf503d27f741f7e
 DIST samba-disable-python-patches-4.5.0_rc1.tar.xz 6204 SHA256 fa0d776e04e3222c0dc4761e376717f4154937cdcb85f4117b8978dfb770a78e SHA512 920089ba3c6e8e7d913b1d7ef1017262a19d1af41215adb30cfc98a57556efc4b0116931d4ef774c01124149d8eca2be3a23814ce7e11daf0180d2c111799927 WHIRLPOOL 6d55710895435ad012e23f8c252e5276966241014710349ca7fa9cf037e8742030b8e053f7cb71309a0a45f48d2235d55393243bf4d19476a22dd39bb1b7748d

diff --git a/net-fs/samba/samba-4.6.7.ebuild b/net-fs/samba/samba-4.6.7.ebuild
new file mode 100644
index 00000000000..a40a90b61b2
--- /dev/null
+++ b/net-fs/samba/samba-4.6.7.ebuild
@@ -0,0 +1,299 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+),xml(+)'
+
+inherit python-single-r1 waf-utils multilib-minimal linux-info systemd eutils
+
+MY_PV="${PV/_rc/rc}"
+MY_P="${PN}-${MY_PV}"
+
+SRC_PATH="stable"
+[[ ${PV} = *_rc* ]] && SRC_PATH="rc"
+
+SRC_URI="mirror://samba/${SRC_PATH}/${MY_P}.tar.gz
+	https://dev.gentoo.org/~polynomial-c/samba-4.6.7-disable-python-patches.tar.xz"
+[[ ${PV} = *_rc* ]] || \
+KEYWORDS="~amd64 ~arm64 ~hppa ~x86"
+
+DESCRIPTION="Samba Suite Version 4"
+HOMEPAGE="http://www.samba.org/"
+LICENSE="GPL-3"
+
+SLOT="0"
+
+IUSE="acl addc addns ads client cluster cups dmapi fam gnutls gpg iprint ldap pam python
+quota selinux syslog system-heimdal +system-mitkrb5 systemd test winbind zeroconf"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/samba-4.0/policy.h
+	/usr/include/samba-4.0/dcerpc_server.h
+	/usr/include/samba-4.0/ctdb.h
+	/usr/include/samba-4.0/ctdb_client.h
+	/usr/include/samba-4.0/ctdb_protocol.h
+	/usr/include/samba-4.0/ctdb_private.h
+	/usr/include/samba-4.0/ctdb_typesafe_cb.h
+	/usr/include/samba-4.0/ctdb_version.h
+)
+
+# sys-apps/attr is an automagic dependency (see bug #489748)
+CDEPEND="
+	>=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}]
+	dev-lang/perl:=
+	dev-libs/libaio[${MULTILIB_USEDEP}]
+	dev-libs/libbsd[${MULTILIB_USEDEP}]
+	dev-libs/iniparser:0
+	dev-libs/popt[${MULTILIB_USEDEP}]
+	dev-python/subunit[${PYTHON_USEDEP},${MULTILIB_USEDEP}]
+	>=dev-util/cmocka-1.0.0[${MULTILIB_USEDEP}]
+	sys-apps/attr[${MULTILIB_USEDEP}]
+	>=sys-libs/ldb-1.1.29[ldap(+)?,python(+),${PYTHON_USEDEP},${MULTILIB_USEDEP}]
+	sys-libs/libcap
+	sys-libs/ncurses:0=[${MULTILIB_USEDEP}]
+	sys-libs/readline:0=
+	>=sys-libs/talloc-2.1.9[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
+	>=sys-libs/tdb-1.3.12[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
+	>=sys-libs/tevent-0.9.31-r1[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	virtual/libiconv
+	pam? ( virtual/pam )
+	acl? ( virtual/acl )
+	addns? (
+		net-dns/bind-tools[gssapi]
+		dev-python/dnspython:=[${PYTHON_USEDEP}]
+	)
+	cluster? ( !dev-db/ctdb )
+	cups? ( net-print/cups )
+	dmapi? ( sys-apps/dmapi )
+	fam? ( virtual/fam )
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=net-libs/gnutls-1.4.0
+	)
+	gpg? ( app-crypt/gpgme )
+	ldap? ( net-nds/openldap[${MULTILIB_USEDEP}] )
+	system-heimdal? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] )
+	system-mitkrb5? ( app-crypt/mit-krb5[${MULTILIB_USEDEP}] )
+	systemd? ( sys-apps/systemd:0= )"
+DEPEND="${CDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	test? (
+		!system-mitkrb5? (
+			>=sys-libs/nss_wrapper-1.1.3
+			>=net-dns/resolv_wrapper-1.1.4
+			>=net-libs/socket_wrapper-1.1.7
+			>=sys-libs/uid_wrapper-1.2.1
+		)
+	)"
+RDEPEND="${CDEPEND}
+	python? ( ${PYTHON_DEPS} )
+	client? ( net-fs/cifs-utils[ads?] )
+	selinux? ( sec-policy/selinux-samba )
+	!dev-perl/Parse-Yapp
+"
+
+REQUIRED_USE="addc? ( python gnutls !system-mitkrb5 )
+	test? ( python )
+	addns? ( python )
+	ads? ( acl gnutls ldap )
+	gpg? ( addc )
+	?? ( system-heimdal system-mitkrb5 )
+	${PYTHON_REQUIRED_USE}"
+
+# the test suite is messed, it uses system-installed samba
+# bits instead of what was built, tests things disabled via use
+# flags, and generally just fails to work in a way ebuilds could
+# rely on in its current state
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.4.0-pam.patch"
+	"${FILESDIR}/${PN}-4.5.1-compile_et_fix.patch"
+)
+
+#CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
+CONFDIR="${FILESDIR}/4.4"
+
+WAF_BINARY="${S}/buildtools/bin/waf"
+
+SHAREDMODS=""
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	if use cluster ; then
+		SHAREDMODS="idmap_rid,idmap_tdb2,idmap_ad"
+	elif use ads ; then
+		SHAREDMODS="idmap_ad"
+	fi
+}
+
+src_prepare() {
+	default
+
+	# install the patches from tarball(s)
+	eapply "${WORKDIR}/patches"
+
+	# un-bundle dnspython
+	sed -i -e '/"dns.resolver":/d' "${S}"/third_party/wscript || die
+
+	# unbundle iso8601 unless tests are enabled
+	use test || sed -i -e '/"iso8601":/d' "${S}"/third_party/wscript || die
+
+	# ugly hackaround for bug #592502
+	cp /usr/include/tevent_internal.h "${S}"/lib/tevent/ || die
+
+	sed -e 's:<gpgme\.h>:<gpgme/gpgme.h>:' \
+		-i source4/dsdb/samdb/ldb_modules/password_hash.c \
+		|| die
+
+	# Friggin' WAF shit
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	# when specifying libs for samba build you must append NONE to the end to 
+	# stop it automatically including things
+	local bundled_libs="NONE"
+	if ! use system-heimdal && ! use system-mitkrb5 ; then
+		bundled_libs="heimbase,heimntlm,hdb,kdc,krb5,wind,gssapi,hcrypto,hx509,roken,asn1,com_err,NONE"
+	fi
+
+	local myconf=()
+	myconf=(
+		--enable-fhs
+		--sysconfdir="${EPREFIX}/etc"
+		--localstatedir="${EPREFIX}/var"
+		--with-modulesdir="${EPREFIX}/usr/$(get_libdir)/samba"
+		--with-piddir="${EPREFIX}/run/${PN}"
+		--bundled-libraries="${bundled_libs}"
+		--builtin-libraries=NONE
+		--disable-rpath
+		--disable-rpath-install
+		--nopyc
+		--nopyo
+	)
+	if multilib_is_native_abi ; then
+		myconf+=(
+			$(use_with acl acl-support)
+			$(usex addc '' '--without-ad-dc')
+			$(use_with addns dnsupdate)
+			$(use_with ads)
+			$(use_with cluster cluster-support)
+			$(use_enable cups)
+			$(use_with dmapi)
+			$(use_with fam)
+			$(use_enable gnutls)
+			$(use_with gpg gpgme)
+			$(use_enable iprint)
+			$(use_with ldap)
+			$(use_with pam)
+			$(usex pam "--with-pammodulesdir=${EPREFIX}/$(get_libdir)/security" '')
+			$(use_with quota quotas)
+			$(use_with syslog)
+			$(use_with systemd)
+			$(usex system-mitkrb5 '--with-system-mitkrb5' '')
+			$(use_with winbind)
+			$(usex python '' '--disable-python')
+			$(usex test '--enable-selftest' '')
+			$(use_enable zeroconf avahi)
+			--with-shared-modules=${SHAREDMODS}
+		)
+	else
+		myconf+=(
+			--without-acl-support
+			--without-ad-dc
+			--without-dnsupdate
+			--without-ads
+			--disable-avahi
+			--without-cluster-support
+			--disable-cups
+			--without-dmapi
+			--without-fam
+			--disable-gnutls
+			--without-gpgme
+			--disable-iprint
+			$(use_with ldap)
+			--without-pam
+			--without-quotas
+			--without-syslog
+			--without-systemd
+			$(usex system-mitkrb5 '--with-system-mitkrb5' '')
+			--without-winbind
+			--disable-python
+		)
+	fi
+
+	CPPFLAGS="-I${SYSROOT}${EPREFIX}/usr/include/et ${CPPFLAGS}" \
+		waf-utils_src_configure ${myconf[@]}
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+
+	# Make all .so files executable
+	find "${D}" -type f -name "*.so" -exec chmod +x {} +
+
+	if multilib_is_native_abi; then
+		# install ldap schema for server (bug #491002)
+		if use ldap ; then
+			insinto /etc/openldap/schema
+			doins examples/LDAP/samba.schema
+		fi
+
+		# create symlink for cups (bug #552310)
+		if use cups ; then
+			dosym /usr/bin/smbspool /usr/libexec/cups/backend/smb
+		fi
+
+		# install example config file
+		insinto /etc/samba
+		doins examples/smb.conf.default
+
+		# Fix paths in example file (#603964)
+		sed \
+			-e '/log file =/s@/usr/local/samba/var/@/var/log/samba/@' \
+			-e '/include =/s@/usr/local/samba/lib/@/etc/samba/@' \
+			-e '/path =/s@/usr/local/samba/lib/@/var/lib/samba/@' \
+			-e '/path =/s@/usr/local/samba/@/var/lib/samba/@' \
+			-e '/path =/s@/usr/spool/samba@/var/spool/samba@' \
+			-i "${ED%/}"/etc/samba/smb.conf.default || die
+
+		# Install init script and conf.d file
+		newinitd "${CONFDIR}/samba4.initd-r1" samba
+		newconfd "${CONFDIR}/samba4.confd" samba
+
+		systemd_dotmpfilesd "${FILESDIR}"/samba.conf
+		systemd_dounit "${FILESDIR}"/nmbd.service
+		systemd_dounit "${FILESDIR}"/smbd.{service,socket}
+		systemd_newunit "${FILESDIR}"/smbd_at.service 'smbd@.service'
+		systemd_dounit "${FILESDIR}"/winbindd.service
+		systemd_dounit "${FILESDIR}"/samba.service
+	fi
+}
+
+multilib_src_test() {
+	if multilib_is_native_abi ; then
+		"${WAF_BINARY}" test || die "test failed"
+	fi
+}
+
+pkg_postinst() {
+	ewarn "Be aware the this release contains the best of all of Samba's"
+	ewarn "technology parts, both a file server (that you can reasonably expect"
+	ewarn "to upgrade existing Samba 3.x releases to) and the AD domain"
+	ewarn "controller work previously known as 'samba4'."
+
+	elog "For further information and migration steps make sure to read "
+	elog "http://samba.org/samba/history/${P}.html "
+	elog "http://samba.org/samba/history/${PN}-4.5.0.html and"
+	elog "http://wiki.samba.org/index.php/Samba4/HOWTO "
+}