[gentoo-commits] repo/gentoo:master commit in: dev-lang/swi-prolog/

[Keri Harris]

commit:     33e8e734511b7d4fd017c83f9c055818a683339e
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 11 14:20:00 2019 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Fri Jan 11 14:20:33 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=33e8e734

dev-lang/swi-prolog: bump development version

Signed-off-by: Keri Harris <keri <AT> gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

 dev-lang/swi-prolog/Manifest                 |  1 +
 dev-lang/swi-prolog/swi-prolog-7.7.24.ebuild | 98 ++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 36649efb07b..6db3584e175 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -6,3 +6,4 @@ DIST swipl-7.6.3.tar.gz 16772590 BLAKE2B 644be801e290ec9d949a9b7462256a35e11cf9a
 DIST swipl-7.6.4.tar.gz 16777875 BLAKE2B 94409966362e649f4748b94b4ec25415bb827c7742aa39453d8e37db4ce992a65ad2d054ded4e651f2a9abe3a9438285bc9c9c895437c087ae6cf88f4afae9ca SHA512 f0ed16e4f1436115651c38a0bb37008d0dadad5a19b0f09894fcfc51dd3d429f86488e89cce00788c3c36cc2f0cd2957f92df47d5441133a6f8ea9d91ca5470f
 DIST swipl-7.7.22.tar.gz 10408402 BLAKE2B e804190a07ad000f054f05bda6c895cae7aa588d6e31a86f17bf2ae4934d747939023035ac8a1b758e5d8e82a39f4a493d19fa41ee323a91333903b7ccb1b78b SHA512 bce8fa4bda39c8841533b4b8d98520b04df3272d8fe49924a49d5c6b7c66ab2defe5d121b1c7fb83506842645258ab6925a1c18740322f468c08e19374f67bfb
 DIST swipl-7.7.23.tar.gz 10422411 BLAKE2B 88a28d290070524d9f552e9d816f70723ac3ceb20dd8ae14e2f894188de024c89157ab68cb692b3a56839580047ebea92f4b6c3c39694b0b0077fd5c4616b30d SHA512 38430827c7f1fd151b448b0c71cd53a59681dfd04b97b8f71c3fcb6d4f86d261f46c3e76d4ebb52e987b665a7505ab5ee1d8528613f9b6bf319d177deb09d28f
+DIST swipl-7.7.24.tar.gz 10433121 BLAKE2B 25efe95c11000fa19ff66ff52ecede8d4fb24c99a4405e1e16313e66947d61f64d572ec1d54017542ea9999258115f647a77a9d7871495b47d6ab3873c2d3f61 SHA512 24c2ffbe7ef9906451490f4b7cfec6afa969a59d265479b659e4287e30c4d00aa977cf55dbe81e560812f517b1270657a360bd917f94660ff2a05fb52efa4cbf

diff --git a/dev-lang/swi-prolog/swi-prolog-7.7.24.ebuild b/dev-lang/swi-prolog/swi-prolog-7.7.24.ebuild
new file mode 100644
index 00000000000..bba3b8614dd
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-7.7.24.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		epatch "${WORKDIR}"/${PV}
+	fi
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	eapply_user
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(usex doc)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}