[gentoo-commits] gentoo-x86 commit in sys-power/upower-pm-utils: upower-pm-utils-0.9.23-r2.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/06/23 04:06:07

  Modified:             ChangeLog
  Added:                upower-pm-utils-0.9.23-r2.ebuild
  Log:
  Import Debian patch to remove last systemd autodetection code to always use sys-power/pm-utils.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.6                  sys-power/upower-pm-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	5 Jun 2014 03:33:54 -0000	1.5
+++ ChangeLog	23 Jun 2014 04:06:07 -0000	1.6
@@ -1,6 +1,14 @@
 # ChangeLog for sys-power/upower-pm-utils
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/ChangeLog,v 1.5 2014/06/05 03:33:54 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/ChangeLog,v 1.6 2014/06/23 04:06:07 ssuominen Exp $
+
+*upower-pm-utils-0.9.23-r2 (23 Jun 2014)
+
+  23 Jun 2014; Samuli Suominen <ssuominen@g.o>
+  +files/upower-pm-utils-0.9.23-always_use_pm-utils_backend.patch,
+  +upower-pm-utils-0.9.23-r2.ebuild:
+  Import Debian patch to remove last systemd autodetection code to always use
+  sys-power/pm-utils.
 
   05 Jun 2014; Samuli Suominen <ssuominen@g.o>
   upower-pm-utils-0.9.23-r1.ebuild:



1.1                  sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r2.ebuild?rev=1.1&content-type=text/plain

Index: upower-pm-utils-0.9.23-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r2.ebuild,v 1.1 2014/06/23 04:06:07 ssuominen Exp $

EAPI=5
inherit eutils systemd

DESCRIPTION="The upstream upower 0.9 git branch for use with sys-power/pm-utils"
HOMEPAGE="http://upower.freedesktop.org/"
SRC_URI="http://upower.freedesktop.org/releases/upower-${PV}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="+introspection ios kernel_FreeBSD kernel_linux"

COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
	>=dev-libs/glib-2.22
	sys-apps/dbus
	>=sys-auth/polkit-0.110
	introspection? ( dev-libs/gobject-introspection )
	kernel_linux? (
		virtual/libusb:1
		virtual/libgudev:=
		virtual/udev
		ios? (
			>=app-pda/libimobiledevice-1:=
			>=app-pda/libplist-1:=
			)
		)
	!sys-power/upower"
RDEPEND="${COMMON_DEPEND}
	kernel_linux? ( >=sys-power/pm-utils-1.4.1-r2 )"
DEPEND="${COMMON_DEPEND}
	dev-libs/libxslt
	app-text/docbook-xsl-stylesheets
	dev-util/intltool
	virtual/pkgconfig"

QA_MULTILIB_PATHS="usr/lib/upower/.*"

DOCS="AUTHORS HACKING NEWS README"

S=${WORKDIR}/upower-${PV}

src_prepare() {
	sed -i -e '/DISABLE_DEPRECATED/d' configure || die

	# http://bugs.freedesktop.org/show_bug.cgi?id=79565
	# http://bugzilla.xfce.org/show_bug.cgi?id=10931
	# Same effect as Debian -no_deprecation_define.patch, they patch .h, we patch .pc
	sed -i -e 's|Cflags: |&-DUPOWER_ENABLE_DEPRECATED |' upower-glib.pc.in || die

	# From upstream 0.9 git branch:
	epatch \
		"${FILESDIR}"/${P}-create-dir-runtime.patch \
		"${FILESDIR}"/${P}-fix-segfault.patch \
		"${FILESDIR}"/${P}-clamp_percentage_for_overfull_batt.patch
	
	# From Debian:
	epatch "${FILESDIR}"/${P}-always_use_pm-utils_backend.patch
}

src_configure() {
	local backend myconf

	if use kernel_linux; then
		backend=linux
		myconf="--enable-deprecated"
	elif use kernel_FreeBSD; then
		backend=freebsd
	else
		backend=dummy
	fi

	econf \
		--libexecdir="${EPREFIX}"/usr/lib/upower \
		--localstatedir="${EPREFIX}"/var \
		$(use_enable introspection) \
		--disable-static \
		${myconf} \
		--enable-man-pages \
		--disable-tests \
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
		--with-backend=${backend} \
		$(use_with ios idevice) \
		"$(systemd_with_utildir)" \
		"$(systemd_with_unitdir)"
}

src_install() {
	default

	# http://bugs.gentoo.org/487400
	insinto /usr/share/doc/${PF}/html/UPower
	doins doc/html/*
	dosym /usr/share/doc/${PF}/html/UPower /usr/share/gtk-doc/html/UPower

	keepdir /var/lib/upower #383091
	prune_libtool_files
}