[gentoo-commits] gentoo-x86 commit in app-misc/dvtm: dvtm-0.5.2.ebuild metadata.xml ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    10/05/04 15:49:45

  Added:                dvtm-0.5.2.ebuild metadata.xml ChangeLog
  Log:
  Initial import from sunrise, bug #206686
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-misc/dvtm/dvtm-0.5.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/dvtm/dvtm-0.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/dvtm/dvtm-0.5.2.ebuild?rev=1.1&content-type=text/plain

Index: dvtm-0.5.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/dvtm/dvtm-0.5.2.ebuild,v 1.1 2010/05/04 15:49:45 chithanh Exp $

EAPI=3

inherit savedconfig toolchain-funcs

DESCRIPTION="Dynamic virtual terminal manager"
HOMEPAGE="http://www.brain-dump.org/projects/dvtm/"
SRC_URI="http://www.brain-dump.org/projects/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="unicode"

DEPEND="sys-libs/ncurses[unicode?]"
RDEPEND=${DEPEND}

src_prepare() {
	sed -i \
		-e 's|FLAGS =|FLAGS +=|' \
		-e 's|-I/usr/local/include||' \
		-e 's|-L/usr/local/lib||' \
		-e 's|-Os||' \
		config.mk || die "sed config.mk failed"
	use unicode || {
		sed -i \
			-e 's|-lncursesw|-lncurses|' \
			config.mk || die "sed config.mk failed"
	}
	sed -i \
		-e '/strip/d' \
		Makefile || die "sed Makefile failed"

	use savedconfig && restore_config config.h
}

src_compile() {
	local msg=""
	use savedconfig && msg=", please check the configfile"
	emake CC=$(tc-getCC) ${PN} || die "emake failed${msg}"
}

src_install() {
	emake DESTDIR="${D}" PREFIX="/usr" install || die "emake install failed"

	insinto /usr/share/${PN}
	newins config.h ${PF}.config.h || die "newins failed"

	dodoc README || die "dodoc failed"

	save_config config.h
}

pkg_postinst() {
	elog "This ebuild has support for user defined configs"
	elog "Please read this ebuild for more details and re-emerge as needed"
	elog "if you want to add or remove functionality for ${PN}"
}



1.1                  app-misc/dvtm/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/dvtm/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/dvtm/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>chithanh@g.o</email>
		<name>Chí-Thanh Christopher Nguyễn</name>
	</maintainer>
</pkgmetadata>




1.1                  app-misc/dvtm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/dvtm/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/dvtm/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-misc/dvtm
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/dvtm/ChangeLog,v 1.1 2010/05/04 15:49:45 chithanh Exp $

*dvtm-0.5.2 (04 May 2010)

  04 May 2010; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
  +dvtm-0.5.2.ebuild, +metadata.xml:
  Initial import from sunrise, bug #206686