[gentoo-commits] gentoo-x86 commit in dev-python/paste: ChangeLog paste-1.7.4.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    10/06/26 04:27:36

  Modified:             ChangeLog
  Added:                paste-1.7.4.ebuild
  Log:
  Version bump. Fix building with USE="doc" (bug #318757).
  (Portage version: HEAD/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 dev-python/paste/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/paste/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/paste/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/paste/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/paste/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	26 Jun 2010 03:38:16 -0000	1.10
+++ ChangeLog	26 Jun 2010 04:27:36 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/paste
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/paste/ChangeLog,v 1.10 2010/06/26 03:38:16 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/paste/ChangeLog,v 1.11 2010/06/26 04:27:36 arfrever Exp $
+
+*paste-1.7.4 (26 Jun 2010)
+
+  26 Jun 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +paste-1.7.4.ebuild:
+  Version bump. Fix building with USE="doc" (bug #318757).
 
   26 Jun 2010; Sebastian Pipping <sping@g.o> paste-1.7.2.ebuild:
   Revert previous commit, shooting too fast, sorry



1.1                  dev-python/paste/paste-1.7.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/paste/paste-1.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/paste/paste-1.7.4.ebuild?rev=1.1&content-type=text/plain

Index: paste-1.7.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/paste/paste-1.7.4.ebuild,v 1.1 2010/06/26 04:27:36 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
DISTUTILS_SRC_TEST="nosetests"

inherit distutils

MY_PN="Paste"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Tools for using a Web Server Gateway Interface stack"
HOMEPAGE="http://pythonpaste.org http://pypi.python.org/pypi/Paste"
SRC_URI="http://pypi.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-interix ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris"
IUSE="doc flup openid"

RDEPEND="flup? ( dev-python/flup )
	openid? ( dev-python/python-openid )"
DEPEND="${RDEPEND}
	dev-python/setuptools
	doc? ( dev-python/sphinx )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	distutils_src_prepare

	sed -i \
		-e '/highlighter/d' \
		setup.cfg || die "sed failed"

	# Disable failing tests.
	rm -f tests/test_cgiapp.py
	sed -e "s/test_logger/_&/" -i tests/test_exceptions/test_reporter.py || die "sed failed"
	sed \
		-e "s/test_find_file/_&/" \
		-e "s/test_deep/_&/" \
		-e "s/test_static_parser/_&/" \
		-i tests/test_urlparser.py || die "sed failed"
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		PYTHONPATH="." "$(PYTHON -f)" setup.py build_sphinx || die "Generation of documentation failed"
	fi
}

# Define custom src_test() due to requirement of PYTHONPATH=".".
src_test() {
	testing() {
		PYTHONPATH="." nosetests
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		pushd build/sphinx/html > /dev/null
		docinto html
		cp -R [a-z]*  _static "${ED}usr/share/doc/${PF}/html" || die "Installation of documentation failed"
		popd > /dev/null
	fi
}