[gentoo-commits] gentoo-x86 commit in net-irc/hexchat: hexchat-2.9.4-r1.ebuild metadata.xml ChangeLog

[Julian Ospald (hasufell)]

hasufell    13/03/31 14:29:27

  Modified:             metadata.xml ChangeLog
  Added:                hexchat-2.9.4-r1.ebuild
  Log:
  revbump: rework, add theme-manager, fix deps, convert to plugin-<..> syntax, use python-single-r1, fix build system instead of sedding it, use eautoreconf rather than autogen.sh, remove obsolete sed, update icon cache and gconf schemas properly
  
  (Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.4                  net-irc/hexchat/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	31 Mar 2013 02:39:23 -0000	1.3
+++ metadata.xml	31 Mar 2013 14:29:27 -0000	1.4
@@ -17,5 +17,10 @@
 		<flag name='ntlm'>Enable NTLM authentication</flag>
 		<flag name='libproxy'>Enable proxy support.</flag>
 		<flag name='plugins'>Enable plugin support and installs some built-in plugins</flag>
+		<flag name='plugin-checksum'>Build Checksum plugin (needs plugins)</flag>
+	    <flag name='plugin-doat'>Build Do At plugin (needs plugins)</flag>
+	    <flag name='plugin-fishlim'>Build FiSHLiM plugin (needs plugins)</flag>
+		<flag name='plugin-sysinfo'>Build SysInfo plugin (needs plugins)</flag>
+		<flag name='theme-manager'>Build the theme manager (mono)</flag>
   </use>
 </pkgmetadata>



1.35                 net-irc/hexchat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	31 Mar 2013 02:39:23 -0000	1.34
+++ ChangeLog	31 Mar 2013 14:29:27 -0000	1.35
@@ -1,6 +1,15 @@
 # ChangeLog for net-irc/hexchat
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.34 2013/03/31 02:39:23 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.35 2013/03/31 14:29:27 hasufell Exp $
+
+*hexchat-2.9.4-r1 (31 Mar 2013)
+
+  31 Mar 2013; Julian Ospald <hasufell@g.o> +hexchat-2.9.4-r1.ebuild,
+  +files/hexchat-2.9.4-build.patch, metadata.xml:
+  revbump: rework, add theme-manager, fix deps, convert to plugin-<..> syntax,
+  use python-single-r1, fix build system instead of sedding it, use eautoreconf
+  rather than autogen.sh, remove obsolete sed, update icon cache and gconf
+  schemas properly
 
   31 Mar 2013; Julian Ospald <hasufell@g.o> metadata.xml:
   add myself to metadata.xml



1.1                  net-irc/hexchat/hexchat-2.9.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.9.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.9.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: hexchat-2.9.4-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-2.9.4-r1.ebuild,v 1.1 2013/03/31 14:29:27 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
inherit autotools eutils gnome2-utils mono multilib flag-o-matic python-single-r1

DESCRIPTION="Graphical IRC client based on XChat"
SRC_URI="mirror://github/${PN}/${PN}/${P}.tar.xz"
HOMEPAGE="http://www.hexchat.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
IUSE="dbus fastscroll +gtk ipv6 libnotify libproxy nls ntlm perl +plugins plugin-checksum plugin-doat plugin-fishlim plugin-sysinfo python spell ssl theme-manager threads"
REQUIRED_USE="plugin-checksum? ( plugins )
	plugin-doat? ( plugins )
	plugin-fishlim? ( plugins )
	plugin-sysinfo? ( plugins )"

RDEPEND="dev-libs/glib:2
	dbus? ( >=dev-libs/dbus-glib-0.98 )
	fastscroll? ( x11-libs/libXft )
	gtk? ( x11-libs/gtk+:2 )
	libproxy? ( net-libs/libproxy )
	libnotify? ( x11-libs/libnotify )
	nls? ( virtual/libintl )
	ntlm? ( net-libs/libntlm )
	perl? ( >=dev-lang/perl-5.8.0 )
	plugin-sysinfo? ( sys-apps/pciutils )
	python? ( ${PYTHON_DEPS} )
	spell? ( dev-libs/libxml2 )
	ssl? ( >=dev-libs/openssl-0.9.8u )
	theme-manager? ( dev-lang/mono )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	nls? ( sys-devel/gettext )
	theme-manager? ( dev-util/monodevelop )"

DOCS="share/doc/changelog.md share/doc/readme.md"

pkg_setup() {
	python-single-r1_pkg_setup

	# Added for to fix a sparc seg fault issue by Jason Wever <weeve@g.o>
	if [[ ${ARCH} = sparc ]] ; then
		replace-flags "-O[3-9]" "-O2"
	fi
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-2.9.1-input-box.patch \
		"${FILESDIR}"/${PN}-2.9.3-cflags.patch \
		"${FILESDIR}"/${PN}-2.9.4-build.patch

	cp $(type -p gettextize) "${T}"/ || die
	sed -i -e 's:read dummy < /dev/tty::' "${T}/gettextize" || die
	einfo "Running gettextize -f --no-changelog..."
	"${T}"/gettextize -f --no-changelog > /dev/null || die "gettexize failed"
	eautoreconf
}

src_configure() {
	# tcl is deprecated/unsupported
	econf \
		--disable-tcl \
		--enable-shm \
		$(use_enable dbus) \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use_enable ntlm) \
		$(use_enable perl) \
		$(usex python "--enable-python=${EPYTHON}" "--disable-python") \
		$(use_enable spell spell static) \
		$(use_enable ssl openssl) \
		$(use_enable gtk gtkfe) \
		$(use_enable !gtk textfe) \
		$(use_enable fastscroll xft) \
		$(use_enable plugins plugin) \
		$(use_enable plugin-checksum checksum) \
		$(use_enable plugin-doat doat) \
		$(use_enable plugin-fishlim fishlim) \
		$(use_enable plugin-sysinfo sysinfo) \
		$(use_enable libproxy) \
		$(use_enable libproxy socks) \
		$(use_enable threads)
}

src_compile() {
	default
	if use theme-manager ; then
		export XDG_CACHE_HOME="${T}/.cache"
		cd src/htm || die
		mdtool --verbose build htm-mono.csproj || die
	fi
}

src_install() {
	default
	if use theme-manager ; then
		dobin src/htm/thememan.exe
		make_wrapper thememan "mono /usr/bin/thememan.exe"
	fi
	prune_libtool_files --all
}

pkg_preinst() {
	if use gtk ; then
		gnome2_icon_savelist
		gnome2_gconf_savelist
	fi
}

pkg_postinst() {
	if use !gtk ; then
		einfo
		elog "You have disabled the gtk USE flag. This means you don't have"
		elog "the GTK-GUI for HexChat but only a text interface called \"hexchat-text\"."
	else
		gnome2_icon_cache_update
		gnome2_gconf_install
	fi

	if use theme-manager ; then
		einfo
		elog "Themes are available at:"
		elog "  http://hexchat.org/themes.html"
	fi

	ewarn
	ewarn "If you're upgrading from hexchat <=2.9.3 remember to rename"
	ewarn "the xchat.conf file found in ~/.config/hexchat/ to hexchat.conf"
	ewarn
}

pkg_postrm() {
	if use gtk ; then
		gnome2_icon_cache_update
	fi
}