[gentoo-commits] gentoo-x86 commit in net-libs/telepathy-glib: telepathy-glib-0.22.1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/02/09 11:45:23

  Modified:             ChangeLog
  Added:                telepathy-glib-0.22.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.143                net-libs/telepathy-glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	8 Dec 2013 19:27:48 -0000	1.142
+++ ChangeLog	9 Feb 2014 11:45:23 -0000	1.143
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/telepathy-glib
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v 1.142 2013/12/08 19:27:48 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v 1.143 2014/02/09 11:45:23 pacho Exp $
+
+*telepathy-glib-0.22.1 (09 Feb 2014)
+
+  09 Feb 2014; Pacho Ramos <pacho@g.o> +telepathy-glib-0.22.1.ebuild:
+  Version bump
 
   08 Dec 2013; Pacho Ramos <pacho@g.o> telepathy-glib-0.20.4.ebuild:
   x86 stable, bug #478252



1.1                  net-libs/telepathy-glib/telepathy-glib-0.22.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.22.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.22.1.ebuild?rev=1.1&content-type=text/plain

Index: telepathy-glib-0.22.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.22.1.ebuild,v 1.1 2014/02/09 11:45:23 pacho Exp $

EAPI="5"
PYTHON_COMPAT=( python2_{6,7} )
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"

inherit eutils gnome2 python-r1 vala virtualx

DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol."
HOMEPAGE="http://telepathy.freedesktop.org"
SRC_URI="http://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"

IUSE="debug +introspection +vala"

# Broken for a long time and upstream don't care
# https://bugs.freedesktop.org/show_bug.cgi?id=63212
RESTRICT="test"

REQUIRED_USE="
	${PYTHON_REQUIRED_USE}
	vala? ( introspection )
"

RDEPEND="
	>=dev-libs/glib-2.32.0:2
	>=dev-libs/dbus-glib-0.90
	introspection? ( >=dev-libs/gobject-introspection-1.30 )
"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	dev-util/gtk-doc-am
	virtual/pkgconfig
	vala? ( $(vala_depend) )
	${PYTHON_DEPS}
"

src_configure() {
	python_export_best

	gnome2_src_configure \
		--disable-static \
		--disable-installed-tests \
		$(use_enable debug backtrace) \
		$(use_enable debug debug-cache) \
		$(use_enable introspection) \
		$(use_enable vala vala-bindings)
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	# Needs dbus for tests (auto-launched)
	Xemake -j1 check
}