[gentoo-commits] repo/gentoo:master commit in: kde-frameworks/kimageformats/

[Andreas Sturmlechner]

commit:     dd992044575c4d9cb53b9a6dcc5feed8f0842bed
Author:     Ionen Wolkens <sudinave <AT> gmail <DOT> com>
AuthorDate: Wed Jan 13 23:17:58 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan 13 23:23:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dd992044

kde-frameworks/kimageformats: add AVIF support to fix automagic

Reported-by: Daniel Novomeský <dnovomesky <AT> gmail.com>
Closes: https://bugs.gentoo.org/764941
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Ionen Wolkens <sudinave <AT> gmail.com>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kimageformats/kimageformats-5.78.0-r1.ebuild   | 39 ++++++++++++++++++++++
 kde-frameworks/kimageformats/metadata.xml          |  1 +
 2 files changed, 40 insertions(+)

diff --git a/kde-frameworks/kimageformats/kimageformats-5.78.0-r1.ebuild b/kde-frameworks/kimageformats/kimageformats-5.78.0-r1.ebuild
new file mode 100644
index 00000000000..3d62edafb6e
--- /dev/null
+++ b/kde-frameworks/kimageformats/kimageformats-5.78.0-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Framework providing additional format plugins for Qt's image I/O system"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="avif eps openexr"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	avif? ( >=media-libs/libavif-0.8.2 )
+	eps? ( >=dev-qt/qtprintsupport-${QTMIN}:5 )
+	openexr? (
+		media-libs/ilmbase:=
+		media-libs/openexr:=
+	)
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( src/imageformats/AUTHORS )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package avif libavif)
+		$(cmake_use_find_package eps Qt5PrintSupport)
+		$(cmake_use_find_package openexr OpenEXR)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-frameworks/kimageformats/metadata.xml b/kde-frameworks/kimageformats/metadata.xml
index 810e5e62b99..c44e1a5290b 100644
--- a/kde-frameworks/kimageformats/metadata.xml
+++ b/kde-frameworks/kimageformats/metadata.xml
@@ -6,6 +6,7 @@
 		<name>Gentoo KDE Project</name>
 	</maintainer>
 	<use>
+		<flag name="avif">Support the AVIF image file format</flag>
 		<flag name="eps">Support the EPS graphics file format</flag>
 	</use>
 </pkgmetadata>