[gentoo-commits] gentoo-x86 commit in media-video/noad: noad-0.7.3-r1.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    13/03/29 09:41:14

  Modified:             ChangeLog
  Added:                noad-0.7.3-r1.ebuild
  Log:
  Enable building marcpics utility because there was no need to disable both, marcpics and showindex when only showindex fails to compile. Remove redudant append-flags -D__STDC_CONSTANT_MACROS because -D__STDC_CONSTANT_MACROS is part of upstream configure.ac. Fix building with recent libc wrt #425288 by Markus Rathgeb and Diego Elio Pettenò. Respect environment CXXFLAGS wrt #426746 by Diego Elio Pettenò.
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.55                 media-video/noad/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/noad/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/noad/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/noad/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/noad/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	5 Jul 2012 15:41:01 -0000	1.54
+++ ChangeLog	29 Mar 2013 09:41:14 -0000	1.55
@@ -1,6 +1,17 @@
 # ChangeLog for media-video/noad
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/noad/ChangeLog,v 1.54 2012/07/05 15:41:01 hd_brummy Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/noad/ChangeLog,v 1.55 2013/03/29 09:41:14 ssuominen Exp $
+
+*noad-0.7.3-r1 (29 Mar 2013)
+
+  29 Mar 2013; Samuli Suominen <ssuominen@g.o>
+  +files/patches-0.7.x/noad-0.7.3_missing_include.diff, +noad-0.7.3-r1.ebuild:
+  Enable building marcpics utility because there was no need to disable both,
+  marcpics and showindex when only showindex fails to compile. Remove redudant
+  append-flags -D__STDC_CONSTANT_MACROS because -D__STDC_CONSTANT_MACROS is
+  part of upstream configure.ac. Fix building with recent libc wrt #425288 by
+  Markus Rathgeb and Diego Elio Pettenò. Respect environment CXXFLAGS wrt
+  #426746 by Diego Elio Pettenò.
 
   05 Jul 2012; Joerg Bornkessel <hd_brummy@g.o> noad-0.7.3.ebuild:
   typo



1.1                  media-video/noad/noad-0.7.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/noad/noad-0.7.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/noad/noad-0.7.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: noad-0.7.3-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/noad/noad-0.7.3-r1.ebuild,v 1.1 2013/03/29 09:41:14 ssuominen Exp $

EAPI=5
inherit autotools eutils

DESCRIPTION="Mark commercial Breaks in VDR records"
HOMEPAGE="http://noad.heliohost.org/"
SRC_URI="http://noad.heliohost.org/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ffmpeg imagemagick"

DEPEND="media-libs/libmpeg2:=
	ffmpeg? ( virtual/ffmpeg )
	imagemagick? ( media-gfx/imagemagick:= )
	!media-plugins/vdr-markad"
RDEPEND="${DEPEND}"

src_prepare() {
	EPATCH_FORCE=yes EPATCH_SUFFIX=diff EPATCH_SOURCE="${FILESDIR}"/patches-${PV%.*}.x epatch

	if has_version '>=media-video/vdr-1.7.15'; then
		sed -i -e 's:2001:6419:' -i svdrpc.cpp || die
	fi

	sed -i -e '/CXXFLAGS.*O3/d' configure.ac || die #426746

	# FIXME: --with-tools, markpics will compile but showindex won't!
	sed -i \
		-e '/^noinst_PROGRAMS/s:@TOOLSRC@::' \
		-e '/^EXTRA_PROGRAMS/s:showindex::' \
		Makefile.am || die

	eautoreconf
}

src_configure() {
	econf \
		$(use_with imagemagick magick) \
		--with-mpeginclude=/usr/include/mpeg2dec \
		--with-tools \
		$(usex ffmpeg '--with-ffmpeg --with-ffmpeginclude=/usr/include' '')
}

src_install() {
	dobin noad # showindex
	use imagemagick && dobin markpics

	dodoc README INSTALL
	# example scripts are installed as dokumentation
	dodoc allnewnoad allnoad allnoadnice clearlogos noadifnew stat2html

	newconfd "${FILESDIR}"/confd_vdraddon.noad vdraddon.noad

	insinto /usr/share/vdr/record
	doins "${FILESDIR}"/record-50-noad.sh

	insinto /usr/share/vdr/shutdown
	doins "${FILESDIR}"/pre-shutdown-15-noad.sh

	insinto /etc/vdr/reccmds
	doins "${FILESDIR}"/reccmds.noad.conf

	exeinto /usr/share/vdr/bin
	doexe "${FILESDIR}"/noad-reccmd
}

pkg_postinst() {
	elog
	elog "To integrate noad in VDR you should do this:"
	elog
	elog "start and set Parameter in /etc/conf.d/vdraddon.noad"
	elog
	elog "Note: You can use here all pararmeters for noad,"
	elog "please look in the documentation of noad."
}