[gentoo-commits] repo/gentoo:master commit in: net-misc/owncloud-client/

[Bernard Cafarelli]

commit:     07ba5afffabfd0bac0cb211352dcafaa16b20b8e
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 15 16:31:11 2021 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Fri Oct 15 16:31:11 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07ba5aff

net-misc/owncloud-client: 2.9.1.5500 bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/owncloud-client/Manifest                  |  1 +
 .../owncloud-client-2.9.1.5500.ebuild              | 69 ++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 6ad0f97ed35..8773e5ac937 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
 DIST ownCloud-2.9.0.5150.tar.xz 5775740 BLAKE2B c43044dd383d66dd212bcd3efd818fad289ac51b082eaa7b47db03778cdfc87725efbdffc567e416bf5444d7e58f795606f093a782ca783cefc2d4994df3fb2a SHA512 c183b2d4340dc8880d2bf31aedaffb96da518fdb60f1e8c857ee2f8d02c36cb69552475fdbf536f7ecebd9af2a7732f52a9e02f20450452c78d346910be3cf57
+DIST ownCloud-2.9.1.5500.tar.xz 5787048 BLAKE2B 6f7df0c1ca13e6074bbd75caaee838ddb822f9284a4f5cc95e1b2c1432adf2969e2413607bebc1542d4bc7790bd6e61edfba758d2205a23fbede6873b7e22316 SHA512 5c78cd0318b7cd35f32721cf364d6e807d32eb1f3651e7f22ff3f3c7737967193ad089062965b3dcee24c23c14cc0d7acdfc95094f4f90f8aaf718f45f22e18a

diff --git a/net-misc/owncloud-client/owncloud-client-2.9.1.5500.ebuild b/net-misc/owncloud-client/owncloud-client-2.9.1.5500.ebuild
new file mode 100644
index 00000000000..ef8aeb7b1ca
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.9.1.5500.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dolphin gnome-keyring nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}