[gentoo-commits] gentoo-x86 commit in sys-apps/module-init-tools: module-init-tools-3.12-r1.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    10/09/04 10:43:02

  Modified:             ChangeLog
  Added:                module-init-tools-3.12-r1.ebuild
  Log:
  Install /etc/modprobe.d/usb-load-ehci-first.conf that will ensure ehci is loaded before uhci or ohci wrt #260139. Thanks to Szymon Zygmunt, Martin Mokrejš, Pacho Ramos and Mike Frysinger.
  
  (Portage version: 2.2_rc69/cvs/Linux x86_64)

Revision  Changes    Path
1.160                sys-apps/module-init-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/module-init-tools/ChangeLog?rev=1.160&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/module-init-tools/ChangeLog?rev=1.160&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/module-init-tools/ChangeLog?r1=1.159&r2=1.160

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/module-init-tools/ChangeLog,v
retrieving revision 1.159
retrieving revision 1.160
diff -u -r1.159 -r1.160
--- ChangeLog	6 Aug 2010 05:56:00 -0000	1.159
+++ ChangeLog	4 Sep 2010 10:43:02 -0000	1.160
@@ -1,6 +1,14 @@
 # ChangeLog for sys-apps/module-init-tools
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/module-init-tools/ChangeLog,v 1.159 2010/08/06 05:56:00 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/module-init-tools/ChangeLog,v 1.160 2010/09/04 10:43:02 ssuominen Exp $
+
+*module-init-tools-3.12-r1 (04 Sep 2010)
+
+  04 Sep 2010; Samuli Suominen <ssuominen@g.o>
+  +module-init-tools-3.12-r1.ebuild:
+  Install /etc/modprobe.d/usb-load-ehci-first.conf that will ensure ehci is
+  loaded before uhci or ohci wrt #260139. Thanks to Szymon Zygmunt, Martin
+  Mokrejš, Pacho Ramos and Mike Frysinger.
 
   06 Aug 2010; Mike Frysinger <vapier@g.o> module-init-tools-3.5.ebuild,
   module-init-tools-3.6-r1.ebuild, module-init-tools-3.8.ebuild,



1.1                  sys-apps/module-init-tools/module-init-tools-3.12-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/module-init-tools/module-init-tools-3.12-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/module-init-tools/module-init-tools-3.12-r1.ebuild?rev=1.1&content-type=text/plain

Index: module-init-tools-3.12-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/module-init-tools/module-init-tools-3.12-r1.ebuild,v 1.1 2010/09/04 10:43:02 ssuominen Exp $

inherit eutils flag-o-matic

DESCRIPTION="tools for managing linux kernel modules"
HOMEPAGE="http://modules.wiki.kernel.org/"
SRC_URI="mirror://kernel/linux/utils/kernel/module-init-tools/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="static"

DEPEND="sys-libs/zlib
	>=sys-apps/baselayout-2.0.1
	!virtual/modutils"
PROVIDE="virtual/modutils"

src_unpack() {
	unpack ${A}
	cd "${S}"
	touch *.5 *.8 # dont regen manpages
}

src_compile() {
	mkdir build && cd build #290207
	use static && append-ldflags -static
	ECONF_SOURCE=.. \
	econf \
		--prefix=/ \
		--enable-zlib \
		--enable-zlib-dynamic \
		--disable-static-utils
	emake || die
}

src_test() {
	./tests/runtests || die
}

src_install() {
	emake -C build install DESTDIR="${D}" || die
	dodoc AUTHORS ChangeLog NEWS README TODO

	into /
	newsbin "${FILESDIR}"/update-modules-3.5.sh update-modules || die
	doman "${FILESDIR}"/update-modules.8 || die

	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
	install ohci_hcd /sbin/modprobe ehci_hcd ; /sbin/modprobe --ignore-install ohci_hcd \$CMDLINE_OPTS
	install uhci_hcd /sbin/modprobe ehci_hcd ; /sbin/modprobe --ignore-install uhci_hcd \$CMDLINE_OPTS
	EOF

	insinto /etc/modprobe.d
	doins "${T}"/usb-load-ehci-first.conf || die #260139
}

pkg_postinst() {
	# cheat to keep users happy
	if grep -qs modules-update "${ROOT}"/etc/init.d/modules ; then
		sed -i 's:modules-update:update-modules:' "${ROOT}"/etc/init.d/modules
	fi

	# For files that were upgraded but not renamed via their ebuild to
	# have a proper .conf extension, rename them so etc-update tools can
	# take care of things. #274942
	local i f cfg
	eshopts_push -s nullglob
	for f in "${ROOT}"etc/modprobe.d/* ; do
		# The .conf files need no upgrading unless a non-.conf exists,
		# so skip this until later ...
		[[ ${f} == *.conf ]] && continue
		# If a .conf doesn't exist, then a package needs updating, or
		# the user created it, or it's orphaned.  Either way, we don't
		# really know, so leave it alone.
		[[ ! -f ${f}.conf ]] && continue

		i=0
		while :; do
			cfg=$(printf "%s/._cfg%04d_%s.conf" "${f%/*}" ${i} "${f##*/}")
			[[ ! -e ${cfg} ]] && break
			((i++))
		done
		elog "Updating ${f}; please run 'etc-update'"
		mv "${f}.conf" "${cfg}"
		mv "${f}" "${f}.conf"
	done
	# Whine about any non-.conf files that are left
	for f in "${ROOT}"etc/modprobe.d/* ; do
		[[ ${f} == *.conf ]] && continue
		ewarn "The '${f}' file needs to be upgraded to end with a '.conf'."
		ewarn "Either upgrade the package that owns it, or manually rename it."
	done
	eshopts_pop
}