[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-keyring: ChangeLog gnome-keyring-2.32.0.ebuild

[Pacho Ramos (pacho)]

pacho       10/10/09 20:53:38

  Modified:             ChangeLog
  Added:                gnome-keyring-2.32.0.ebuild
  Log:
  Version bump for Gnome 2.32
  
  (Portage version: 2.1.9.14/cvs/Linux x86_64)

Revision  Changes    Path
1.186                gnome-base/gnome-keyring/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/ChangeLog?rev=1.186&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/ChangeLog?rev=1.186&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/ChangeLog?r1=1.185&r2=1.186

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/ChangeLog,v
retrieving revision 1.185
retrieving revision 1.186
diff -u -r1.185 -r1.186
--- ChangeLog	9 Oct 2010 10:01:44 -0000	1.185
+++ ChangeLog	9 Oct 2010 20:53:38 -0000	1.186
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-base/gnome-keyring
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/ChangeLog,v 1.185 2010/10/09 10:01:44 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/ChangeLog,v 1.186 2010/10/09 20:53:38 pacho Exp $
+
+*gnome-keyring-2.32.0 (09 Oct 2010)
+
+  09 Oct 2010; Pacho Ramos <pacho@g.o> +gnome-keyring-2.32.0.ebuild:
+  Version bump for Gnome 2.32: New GPG Agent built into
+  gnome-keyring-daemon, fix broken startup when used with gdm and
+  password-less login, other bugfixes and translation updates. Remove
+  DISABLE_DEPRECATED flags.
 
   09 Oct 2010; Samuli Suominen <ssuominen@g.o>
   gnome-keyring-2.30.3.ebuild:



1.1                  gnome-base/gnome-keyring/gnome-keyring-2.32.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-2.32.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-2.32.0.ebuild?rev=1.1&content-type=text/plain

Index: gnome-keyring-2.32.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-2.32.0.ebuild,v 1.1 2010/10/09 20:53:38 pacho Exp $

EAPI="3"
GCONF_DEBUG="yes"

inherit gnome2 pam virtualx

DESCRIPTION="Password and keyring managing daemon"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="debug doc pam test"
# USE=valgrind is probably not a good idea for the tree

RDEPEND=">=dev-libs/glib-2.25.0
	>=x11-libs/gtk+-2.20.0
	gnome-base/gconf
	>=sys-apps/dbus-1.0
	pam? ( virtual/pam )
	>=dev-libs/libgcrypt-1.2.2
	>=dev-libs/libtasn1-1"
#	valgrind? ( dev-util/valgrind )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.9
	>=dev-util/gtk-doc-am-1.9
	doc? ( >=dev-util/gtk-doc-1.9 )"
PDEPEND="gnome-base/libgnome-keyring"

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable debug)
		$(use_enable test tests)
		$(use_enable pam)
		$(use_with pam pam-dir $(getpam_mod_dir))
		--with-root-certs=/usr/share/ca-certificates/
		--enable-acl-prompts
		--enable-ssh-agent
		--enable-gpg-agent
		--with-gtk=2.0"
#		$(use_enable valgrind)
}

src_prepare() {
	gnome2_src_prepare

	# Remove silly CFLAGS
	sed 's:CFLAGS="$CFLAGS -Werror:CFLAGS="$CFLAGS:' \
		-i configure.in configure || die "sed failed"

	# Remove DISABLE_DEPRECATED flags
	sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' \
		-i configure.in configure || die "sed 2 failed"
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "emake check failed!"
}