[gentoo-commits] gentoo-x86 commit in www-client/midori: ChangeLog midori-0.2.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/10/28 13:44:10

  Modified:             ChangeLog
  Added:                midori-0.2.0.ebuild
  Log:
  Version bump (missing libsoup >= 2.27.90 for full functionality) wrt #290599, thanks to Jan Aniŝĉuk for reporting.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.20                 www-client/midori/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/midori/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/midori/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/midori/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	14 Sep 2009 16:12:14 -0000	1.19
+++ ChangeLog	28 Oct 2009 13:44:10 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.19 2009/09/14 16:12:14 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.20 2009/10/28 13:44:10 ssuominen Exp $
+
+*midori-0.2.0 (28 Oct 2009)
+
+  28 Oct 2009; Samuli Suominen <ssuominen@g.o> +midori-0.2.0.ebuild:
+  Version bump (missing libsoup >= 2.27.90 for full functionality) wrt
+  #290599, thanks to Jan Aniŝĉuk for reporting.
 
   14 Sep 2009; Jeremy Olexa <darkside@g.o> midori-9999.ebuild:
   modified -9999 ebuild to match 0.1.10 (improvements in build quality and



1.1                  www-client/midori/midori-0.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/midori/midori-0.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/midori/midori-0.2.0.ebuild?rev=1.1&content-type=text/plain

Index: midori-0.2.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.2.0.ebuild,v 1.1 2009/10/28 13:44:10 ssuominen Exp $

EAPI=2
inherit xfconf multilib

DESCRIPTION="A lightweight web browser"
HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
SRC_URI="http://archive.xfce.org/src/apps/${PN}/0.2/${P}.tar.bz2"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="doc gnome html idn libnotify nls +sqlite +unique"

RDEPEND="libnotify? ( x11-libs/libnotify )
	>=net-libs/libsoup-2.25.2
	>=net-libs/webkit-gtk-1.1.1
	dev-libs/libxml2
	>=x11-libs/gtk+-2.10:2
	gnome? ( net-libs/libsoup[gnome] )
	idn? ( net-dns/libidn )
	sqlite? ( >=dev-db/sqlite-3.0 )
	unique? ( dev-libs/libunique )"

DEPEND="${RDEPEND}
	dev-lang/python
	dev-util/pkgconfig
	doc? ( dev-util/gtk-doc )
	html? ( dev-python/docutils )
	nls? ( sys-devel/gettext )"

src_prepare() {
	# moving docs to version-specific directory
	sed -i -e "s:\${DOCDIR}/${PN}:\${DOCDIR}/${PF}/:g" wscript
	sed -i -e "s:/${PN}/user/midori.html:/${PF}/user/midori.html:g" midori/midori-browser.c
}

src_configure() {
	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf \
		--prefix="/usr/" \
		--libdir="/usr/$(get_libdir)" \
		--disable-docs \
		$(use_enable doc apidocs) \
		$(use_enable html userdocs) \
		$(use_enable idn libidn) \
		$(use_enable nls nls) \
		$(use_enable sqlite) \
		$(use_enable unique) \
		configure || die "configure failed"
}

src_compile() {
	NUMJOBS=$(sed -e 's/.*\(\-j[ 0-9]\+\) .*/\1/; s/--jobs=\?/-j/' <<< ${MAKEOPTS})
	./waf build ${NUMJOBS} || die "build failed"
}

src_install() {
	DESTDIR=${D} ./waf install || die "install failed"
	rm -r ${D}/usr/share/doc/${PN}
	dodoc AUTHORS ChangeLog INSTALL TODO || die "dodoc failed"
}

pkg_postinst() {
	xfconf_pkg_postinst
	ewarn "Midori tends to crash due to bugs in WebKit."
	ewarn "Report bugs at http://www.twotoasts.de/bugs"
}