[gentoo-commits] gentoo-x86 commit in sys-cluster/cluster-glue: ChangeLog cluster-glue-1.0.11.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    12/10/29 12:21:30

  Modified:             ChangeLog
  Added:                cluster-glue-1.0.11.ebuild
  Log:
  Version bump cluster-glue-1.0.11
  
  (Portage version: 2.1.11.30/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.27                 sys-cluster/cluster-glue/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	19 Sep 2012 22:50:45 -0000	1.26
+++ ChangeLog	29 Oct 2012 12:21:30 -0000	1.27
@@ -1,6 +1,11 @@
 # ChangeLog for sys-cluster/cluster-glue
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v 1.26 2012/09/19 22:50:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v 1.27 2012/10/29 12:21:30 ultrabug Exp $
+
+*cluster-glue-1.0.11 (29 Oct 2012)
+
+  29 Oct 2012; Ultrabug <ultrabug@g.o> +cluster-glue-1.0.11.ebuild:
+  Version bump.
 
   19 Sep 2012; Jeroen Roovers <jer@g.o> cluster-glue-1.0.10.ebuild:
   Stable for HPPA (bug #433359).



1.1                  sys-cluster/cluster-glue/cluster-glue-1.0.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.11.ebuild?rev=1.1&content-type=text/plain

Index: cluster-glue-1.0.11.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.11.ebuild,v 1.1 2012/10/29 12:21:30 ultrabug Exp $

EAPI=4

MY_P="${P/cluster-}"
inherit autotools multilib eutils base

DESCRIPTION="Library pack for Heartbeat / Pacemaker"
HOMEPAGE="http://www.linux-ha.org/wiki/Cluster_Glue"
SRC_URI="http://hg.linux-ha.org/glue/archive/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE="doc libnet static-libs"

RDEPEND="app-arch/bzip2
	dev-libs/glib:2
	dev-libs/libaio
	libnet? ( net-libs/libnet:1.1 )
	net-misc/curl
	net-misc/iputils
	|| ( net-misc/netkit-telnetd net-misc/telnet-bsd )
	dev-libs/libxml2
	!<sys-cluster/heartbeat-3.0"
DEPEND="${RDEPEND}
	doc? (
		dev-libs/libxslt
		app-text/docbook-xsl-stylesheets
		)"

S="${WORKDIR}/Reusable-Cluster-Components-glue--${MY_P}"

PATCHES=(
	"${FILESDIR}/1.0.5-respect_cflags.patch"
)

pkg_setup() {
	enewgroup haclient
	enewuser  hacluster -1 /dev/null /var/lib/heartbeat haclient
}

src_prepare() {
	base_src_prepare
	sed -e "s@http://docbook.sourceforge.net/release/xsl/current@/usr/share/sgml/docbook/xsl-stylesheets/@g" \
		-i doc/Makefile.am || die
	eautoreconf
}

src_configure() {
	local myopts

	use doc && myopts=" --enable-doc"
	econf \
		$(use_enable libnet) \
		$(use_enable static-libs static) \
		--disable-fatal-warnings \
		--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		--localstatedir=/var \
		--with-ocf-root=/usr/$(get_libdir)/ocf \
		${myopts} \
		--with-group-id=$(id -g hacluster) \
		--with-ccmuser-id=$(id -u hacluster) \
		--with-daemon-user=hacluster --with-daemon-group=haclient
}

src_install() {
	base_src_install

	dodir /var/lib/heartbeat/cores
	dodir /var/lib/heartbeat/lrm

	keepdir /var/lib/heartbeat/cores
	keepdir /var/lib/heartbeat/lrm

	# init.d file
	cp "${FILESDIR}"/heartbeat-logd.init "${T}/" || die
	sed -i \
		-e "s:%libdir%:$(get_libdir):" \
		"${T}/heartbeat-logd.init" || die
	newinitd "${T}/heartbeat-logd.init" heartbeat-logd || die
	rm "${D}"/etc/init.d/logd

	use static-libs || find "${D}" -type f -name "*.la" -delete
}

pkg_postinst() {
	chown -R hacluster:haclient /var/lib/heartbeat/cores
	chown -R hacluster:haclient /var/lib/heartbeat/lrm
}