[gentoo-commits] repo/gentoo:master commit in: net-libs/libnxml/

[David Seifert]

commit:     c167246c3c5a7276b034688d9b97def591c737a3
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  9 18:49:48 2020 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Feb  9 18:49:48 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c167246c

net-libs/libnxml: Port to EAPI 7

Package-Manager: Portage-2.3.88, Repoman-2.3.20
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 net-libs/libnxml/libnxml-0.18.3.ebuild | 31 +++++++++++++++----------------
 1 file changed, 15 insertions(+), 16 deletions(-)

diff --git a/net-libs/libnxml/libnxml-0.18.3.ebuild b/net-libs/libnxml/libnxml-0.18.3.ebuild
index 259c8a928c0..8d4062c2bd0 100644
--- a/net-libs/libnxml/libnxml-0.18.3.ebuild
+++ b/net-libs/libnxml/libnxml-0.18.3.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="4"
+EAPI=7
 
 DESCRIPTION="A C-library for parsing and writing XML 1.0/1.1 files or streams"
 HOMEPAGE="http://www.autistici.org/bakunin/libnxml/doc/"
@@ -10,23 +10,25 @@ SRC_URI="http://www.autistici.org/bakunin/${PN}/${P}.tar.gz"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="amd64 ~arm ~mips ppc ~sparc x86"
-IUSE="doc examples static-libs"
+IUSE="doc examples"
 
 RDEPEND="net-misc/curl"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
 
 src_configure() {
-	econf \
-		$(use_enable static-libs static)
+	econf --disable-static
 }
 
 src_compile() {
-	emake
+	default
 
 	if use doc; then
 		ebegin "Creating documentation"
-		doxygen doxy.conf || die "creating docs failed"
+		doxygen doxy.conf || die "generating docs failed"
+		# clean out doxygen gunk
+		rm doc/html/*.{md5,map} || die
+		HTML_DOCS=( doc/html/. )
 		eend 0
 	fi
 }
@@ -34,14 +36,11 @@ src_compile() {
 src_install() {
 	default
 
-	if use doc; then
-		dohtml doc/html/*
-	fi
-
 	if use examples; then
-		insinto /usr/share/doc/${PF}/test
-		doins test/*.c
+		docinto test
+		dodoc test/*.c
 	fi
 
-	find "${D}" -name '*.la' -delete
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
 }