[gentoo-commits] proj/kde:master commit in: kde-apps/umbrello/

[Andreas Sturmlechner]

commit:     2b13738c2fc4822a3efb081458b6521d1564a3c3
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  1 09:03:20 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Mar  1 09:03:20 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=2b13738c

kde-apps/umbrello: 21.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/umbrello/umbrello-21.12.3.ebuild | 75 +++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)

diff --git a/kde-apps/umbrello/umbrello-21.12.3.ebuild b/kde-apps/umbrello/umbrello-21.12.3.ebuild
new file mode 100644
index 0000000000..49746bb538
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-21.12.3.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.88.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-no-qtwebkit.patch
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}