[gentoo-commits] gentoo-x86 commit in sci-libs/scipy: ChangeLog scipy-0.6.0-r1.ebuild

[Markus Dittrich (markusle)]

markusle    07/10/05 14:01:38

  Modified:             ChangeLog
  Added:                scipy-0.6.0-r1.ebuild
  Log:
  New revision with patch to fix fftw problem (see bug #194708).
  (Portage version: 2.1.3.11)

Revision  Changes    Path
1.24                 sci-libs/scipy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/scipy/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/scipy/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/scipy/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/scipy/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	25 Sep 2007 21:54:57 -0000	1.23
+++ ChangeLog	5 Oct 2007 14:01:38 -0000	1.24
@@ -1,6 +1,13 @@
 # ChangeLog for sci-libs/scipy
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/ChangeLog,v 1.23 2007/09/25 21:54:57 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/ChangeLog,v 1.24 2007/10/05 14:01:38 markusle Exp $
+
+*scipy-0.6.0-r1 (05 Oct 2007)
+
+  05 Oct 2007; Markus Dittrich <markusle@g.o>
+  +files/scipy-0.6.0-fftw-fix.patch, +scipy-0.6.0-r1.ebuild:
+  New revision with patch to fix fftw problem (see bug #194708). 
+  Thanks much to David Heavens <david.heavens@×××××.com> for his patch.
 
 *scipy-0.6.0 (25 Sep 2007)
 



1.1                  sci-libs/scipy/scipy-0.6.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/scipy/scipy-0.6.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/scipy/scipy-0.6.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: scipy-0.6.0-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/scipy-0.6.0-r1.ebuild,v 1.1 2007/10/05 14:01:38 markusle Exp $

NEED_PYTHON=2.3

inherit eutils distutils fortran

SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
DESCRIPTION="Scientific algorithms library for Python"
HOMEPAGE="http://www.scipy.org/"
LICENSE="BSD"

SLOT="0"

IUSE="fftw umfpack sandbox"

KEYWORDS="~amd64 ~ppc ~x86"

DEPEND=">=dev-python/numpy-1.0.3.1
	virtual/lapack
	fftw? ( =sci-libs/fftw-2.1* )
	umfpack? ( sci-libs/umfpack dev-lang/swig )
	sandbox? ( >=sci-libs/netcdf-3.6 x11-libs/libX11 )"

RDEPEND=">=dev-python/numpy-1.0.3.1
	dev-python/imaging
	virtual/lapack
	fftw? ( =sci-libs/fftw-2.1* )
	umfpack? ( sci-libs/umfpack )
	sandbox? ( >=sci-libs/netcdf-3.6 x11-libs/libX11 )"

# test still buggy on lapack with 2 failures on check_syevr
# (lapack float). check every version bump.
RESTRICT="test"

DOCS="THANKS.txt DEVELOPERS.txt LATEST.txt TOCHANGE.txt FORMAT_GUIDELINES.txt"

scipy_fortran_setup() {
	FORTRAN="gfortran g77 ifc"
	fortran_pkg_setup
	local fc=
	case ${FORTRANC} in
		gfortran) fc=gnu95 ;;
		g77) fc=gnu ;;
		ifc|ifort)
			if use ia64; then
				fc=intele
			elif use amd64; then
				fc=intelem
			else
				fc=intel
			fi
			;;
		*)	eerror "Unknown fortran compiler: ${FORTRANC}"
			die "scipy_fortran_setup failed" ;;
	esac

	# when fortran flags are set, pic is removed.
	use amd64 && [[ -n ${FFLAGS} ]] && FFLAGS="${FFLAGS} -fPIC"
	export SCIPY_FCONFIG="config_fc --fcompiler=${fc}"
}

# see numpy ebuild about unsetting LDFLAGS
LDFLAGS_sav="${LDFLAGS}"
unset LDFLAGS

pkg_setup() {
	[[ -n ${LDFLAGS_sav} ]] && einfo "Ignoring LDFLAGS=${LDFLAGS_sav}"
	if use umfpack && ! built_with_use dev-lang/swig python; then
		eerror "With umfpack enabled you need"
		eerror "dev-lang/swig with python enabled"
		einfo  "Please re-emerge swig with USE=python"
		die "needs swig with python"
	fi
	# scipy automatically detects libraries by default
	export FFTW=None FFTW3=None UMFPACK=None DJBFFT=None
	use fftw && unset FFTW
	use umfpack && unset UMFPACK
	use sandbox && elog "Warning: using sandbox modules at your own risk!"
	scipy_fortran_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-randomkit.patch
	epatch "${FILESDIR}"/${P}-cdf.patch
	epatch "${FILESDIR}"/${P}-fftw-fix.patch

	if use sandbox; then
		cd scipy/sandbox
		ls -1 */__init__.py \
			| sed -e 's:/__init__.py::' \
			| grep -v exmplpackage \
			> enabled_packages.txt \
			|| die "sandbox listing failed"
	fi
}

src_compile() {
	distutils_src_compile ${SCIPY_FCONFIG}
}

src_test() {
	"${python}" setup.py install \
		--home="${S}"/test \
		--no-compile \
		${SCIPY_FCONFIG} || die "install test failed"
	pushd "${S}"/test/lib*/python
	PYTHONPATH=. "${python}" -c \
		"import scipy as s;import sys;sys.exit(s.test(10,3))" \
		 2>&1 | tee test.log
	grep -q OK test.log || die "test failed"
	popd
	rm -rf test
}

src_install() {
	distutils_src_install ${SCIPY_FCONFIG}
}

pkg_postinst() {
	elog "You might want to set the variable SCIPY_PIL_IMAGE_VIEWER"
	elog "to your prefered image viewer if you don't like the default one. Ex:"
	elog "\t echo \"export SCIPY_PIL_IMAGE_VIEWER=display\" >> ~/.bashrc"
}



-- 
gentoo-commits@g.o mailing list