[gentoo-commits] repo/gentoo:master commit in: dev-python/tree-sitter/

[Michał Górny]

commit:     402d73e94e5a57a80aab6e9f5f8f25a82a5981d6
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May 19 12:44:59 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May 19 12:53:39 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=402d73e9

dev-python/tree-sitter: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../tree-sitter/tree-sitter-0.20.0-r1.ebuild       | 65 ++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/dev-python/tree-sitter/tree-sitter-0.20.0-r1.ebuild b/dev-python/tree-sitter/tree-sitter-0.20.0-r1.ebuild
new file mode 100644
index 000000000000..b5e5fb8d350d
--- /dev/null
+++ b/dev-python/tree-sitter/tree-sitter-0.20.0-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+EGIT_COMMIT="4f39f6919ca3be8efb420a338fd2cf9b8b68b156"
+MY_P=py-tree-sitter-${EGIT_COMMIT}
+FIXTURE_PV=0.19.0
+
+DESCRIPTION="Python bindings to the Tree-sitter parsing library"
+HOMEPAGE="
+	https://github.com/tree-sitter/py-tree-sitter/
+	https://pypi.org/project/tree-sitter/
+"
+SRC_URI="
+	https://github.com/tree-sitter/py-tree-sitter/archive/${EGIT_COMMIT}.tar.gz
+		-> ${MY_P}.tar.gz
+	test? (
+		https://github.com/tree-sitter/tree-sitter-javascript/archive/v${FIXTURE_PV}.tar.gz
+			-> tree-sitter-javascript-${FIXTURE_PV}.tar.gz
+		https://github.com/tree-sitter/tree-sitter-python/archive/v${FIXTURE_PV}.tar.gz
+			-> tree-sitter-python-${FIXTURE_PV}.tar.gz
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-libs/tree-sitter:=
+"
+DEPEND="
+	${RDEPEND}
+"
+
+distutils_enable_tests unittest
+
+PATCHES=(
+	"${FILESDIR}"/tree-sitter-0.19.0_p20210506-unbundle.patch
+)
+
+src_unpack() {
+	default
+	rmdir "${S}/tree_sitter/core" || die
+
+	if use test; then
+		mkdir "${S}/tests/fixtures" || die
+		local f
+		for f in tree-sitter-{javascript,python}; do
+			mv "${f}-${FIXTURE_PV}" "${S}/tests/fixtures/${f}" || die
+		done
+	fi
+}
+
+src_test() {
+	rm -r tree_sitter || die
+	distutils-r1_src_test
+}