[gentoo-commits] gentoo-x86 commit in app-crypt/mit-krb5: ChangeLog mit-krb5-1.10.2.ebuild

[Eray Aslan (eras)]

eras        12/06/05 14:13:02

  Modified:             ChangeLog
  Added:                mit-krb5-1.10.2.ebuild
  Log:
  security bump - bug #419765
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.321                app-crypt/mit-krb5/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/ChangeLog?rev=1.321&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/ChangeLog?rev=1.321&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/ChangeLog?r1=1.320&r2=1.321

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v
retrieving revision 1.320
retrieving revision 1.321
diff -u -r1.320 -r1.321
--- ChangeLog	21 Apr 2012 12:14:24 -0000	1.320
+++ ChangeLog	5 Jun 2012 14:13:02 -0000	1.321
@@ -1,6 +1,11 @@
 # ChangeLog for app-crypt/mit-krb5
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v 1.320 2012/04/21 12:14:24 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v 1.321 2012/06/05 14:13:02 eras Exp $
+
+*mit-krb5-1.10.2 (05 Jun 2012)
+
+  05 Jun 2012; Eray Aslan <eras@g.o> +mit-krb5-1.10.2.ebuild:
+  security bump - bug #419765
 
   21 Apr 2012; Markus Meier <maekke@g.o> mit-krb5-1.10.1-r3.ebuild:
   add ~arm, bug #412489



1.1                  app-crypt/mit-krb5/mit-krb5-1.10.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.10.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.10.2.ebuild?rev=1.1&content-type=text/plain

Index: mit-krb5-1.10.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.10.2.ebuild,v 1.1 2012/06/05 14:13:02 eras Exp $

EAPI=4
inherit eutils flag-o-matic versionator

MY_P="${P/mit-}"
P_DIR=$(get_version_component_range 1-2)
DESCRIPTION="MIT Kerberos V"
HOMEPAGE="http://web.mit.edu/kerberos/www/"
SRC_URI="http://web.mit.edu/kerberos/dist/krb5/${P_DIR}/${MY_P}-signed.tar"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~x86"
IUSE="doc +keyutils openldap +pkinit +threads test xinetd"

RDEPEND="!!app-crypt/heimdal
	>=sys-libs/e2fsprogs-libs-1.41.0
	dev-libs/libverto
	keyutils? ( sys-apps/keyutils )
	openldap? ( net-nds/openldap )
	xinetd? ( sys-apps/xinetd )"
DEPEND="${RDEPEND}
	virtual/yacc
	doc? ( virtual/latex-base )
	test? ( dev-lang/tcl
	        dev-lang/python
			dev-util/dejagnu )"

S=${WORKDIR}/${MY_P}/src

src_unpack() {
	unpack ${A}
	unpack ./"${MY_P}".tar.gz
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.10.1_uninitialized_extra.patch"
	epatch "${FILESDIR}/${PN}-1.10.1_uninitialized_extra-2.patch"
	epatch "${FILESDIR}/${PN}-1.10.1_gcc470.patch"
}

src_configure() {
	append-cppflags "-I${EPREFIX}/usr/include/et"
	# QA
	append-flags -fno-strict-aliasing
	append-flags -fno-strict-overflow
	[[ $(gcc-version) == "4.7" ]] && replace-flags -O? -O0

	use keyutils || export ac_cv_header_keyutils_h=no
	econf \
		$(use_with openldap ldap) \
		"$(use_with test tcl "${EPREFIX}/usr")" \
		$(use_enable pkinit) \
		$(use_enable threads thread-support) \
		--without-hesiod \
		--enable-shared \
		--with-system-et \
		--with-system-ss \
		--enable-dns-for-realm \
		--enable-kdc-lookaside-cache \
		--with-system-verto \
		--disable-rpath
}

src_compile() {
	emake -j1

	if use doc ; then
		cd ../doc
		for dir in api implement ; do
			emake -C "${dir}"
		done
	fi
}

src_install() {
	emake \
		DESTDIR="${D}" \
		EXAMPLEDIR="${EPREFIX}/usr/share/doc/${PF}/examples" \
		install

	# default database dir
	keepdir /var/lib/krb5kdc

	cd ..
	dodoc NOTICE README
	dodoc doc/*.{ps,txt}
	doinfo doc/*.info*
	dohtml -r doc/*.html

	if use doc ; then
	    dodoc doc/{api,implement}/*.ps
	fi

	newinitd "${FILESDIR}"/mit-krb5kadmind.initd mit-krb5kadmind
	newinitd "${FILESDIR}"/mit-krb5kdc.initd mit-krb5kdc
	newinitd "${FILESDIR}"/mit-krb5kpropd.initd mit-krb5kpropd

	insinto /etc
	newins "${ED}/usr/share/doc/${PF}/examples/krb5.conf" krb5.conf.example
	insinto /var/lib/krb5kdc
	newins "${ED}/usr/share/doc/${PF}/examples/kdc.conf" kdc.conf.example

	if use openldap ; then
		insinto /etc/openldap/schema
		doins "${S}/plugins/kdb/ldap/libkdb_ldap/kerberos.schema"
	fi

	if use xinetd ; then
		insinto /etc/xinetd.d
		newins "${FILESDIR}/kpropd.xinetd" kpropd
	fi
}

pkg_preinst() {
	if has_version "<${CATEGORY}/${PN}-1.8.0" ; then
		elog "MIT split the Kerberos applications from the base Kerberos"
		elog "distribution.  Kerberized versions of telnet, rlogin, rsh, rcp,"
		elog "ftp clients and telnet, ftp deamons now live in"
		elog "\"app-crypt/mit-krb5-appl\" package."
	fi
}