[gentoo-commits] gentoo-x86 commit in sys-boot/plymouth: metadata.xml ChangeLog plymouth-0.8.3-r5.ebuild

[Amadeusz Zolnowski (aidecoe)]

aidecoe     11/07/03 10:06:14

  Modified:             metadata.xml ChangeLog
  Added:                plymouth-0.8.3-r5.ebuild
  Log:
  sys-boot/plymouth: revbump to 0.8.3-r5; fixes bug #372699; del 'branding' flag
  
  Split plymouth-openrc-plugin from sys-boot/plymouth. 'branding' flag was
  abandoned and Gentoo logo is installed unconditionally now.  New 'openrc' flag
  pulls sys-boot/plymouth-openrc-plugin.
  
  (Portage version: 2.1.10.3/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  sys-boot/plymouth/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/plymouth/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	21 Feb 2011 21:08:17 -0000	1.1
+++ metadata.xml	3 Jul 2011 10:06:14 -0000	1.2
@@ -7,7 +7,8 @@
 		<name>Amadeusz Żołnowski</name>
 	</maintainer>
 	<use>
-		<flag name="gdm">Enable smooth transition to GDM</flag>
+		<flag name="gdm">Enables smooth transition to GDM</flag>
+		<flag name="openrc">Installs plugin for OpenRC</flag>
 		<flag name="pango">Adds support for printing text on splash screen and
 			text prompts, e.g. for password</flag>
 	</use>



1.14                 sys-boot/plymouth/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	28 Jun 2011 21:51:11 -0000	1.13
+++ ChangeLog	3 Jul 2011 10:06:14 -0000	1.14
@@ -1,6 +1,14 @@
 # ChangeLog for sys-boot/plymouth
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v 1.13 2011/06/28 21:51:11 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v 1.14 2011/07/03 10:06:14 aidecoe Exp $
+
+*plymouth-0.8.3-r5 (03 Jul 2011)
+
+  03 Jul 2011; Amadeusz Żołnowski <aidecoe@g.o>
+  +plymouth-0.8.3-r5.ebuild, metadata.xml:
+  Split plymouth-openrc-plugin from sys-boot/plymouth. 'branding' flag was
+  abandoned and Gentoo logo is installed unconditionally now.  New 'openrc'
+  flag pulls sys-boot/plymouth-openrc-plugin.  Fixes bug #372699.
 
   28 Jun 2011; Amadeusz Żołnowski <aidecoe@g.o>
   plymouth-0.8.3-r2.ebuild, plymouth-0.8.3-r4.ebuild:



1.1                  sys-boot/plymouth/plymouth-0.8.3-r5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/plymouth-0.8.3-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/plymouth-0.8.3-r5.ebuild?rev=1.1&content-type=text/plain

Index: plymouth-0.8.3-r5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/plymouth-0.8.3-r5.ebuild,v 1.1 2011/07/03 10:06:14 aidecoe Exp $

EAPI="3"

inherit autotools-utils

DESCRIPTION="Graphical boot animation (splash) and logger"
HOMEPAGE="http://cgit.freedesktop.org/plymouth/"
SRC_URI="http://cgit.freedesktop.org/${PN}/snapshot/${P}.tar.bz2
	http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png
	"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE_VIDEO_CARDS="video_cards_intel video_cards_nouveau video_cards_radeon"
IUSE="${IUSE_VIDEO_CARDS} gdm +openrc +pango static-libs"

COMMON_DEPEND=">=media-libs/libpng-1.2.16
	>=x11-libs/gtk+-2.12:2
	pango? ( >=x11-libs/pango-1.21 )
	video_cards_intel? ( x11-libs/libdrm[video_cards_intel] )
	video_cards_nouveau? ( x11-libs/libdrm[video_cards_nouveau] )
	video_cards_radeon? ( x11-libs/libdrm[video_cards_radeon] )
	"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	"
RDEPEND="${COMMON_DEPEND}
	>=sys-kernel/dracut-008-r1[dracut_modules_plymouth]
	openrc? ( sys-boot/plymouth-openrc-plugin )
	"

DOCS=(AUTHORS ChangeLog NEWS README TODO)

PATCHES=(
	"${FILESDIR}"/${PV}-drm-reduce-minimum-build-requirements.patch
	"${FILESDIR}"/${PV}-image-replace-deprecated-libpng-function.patch
	"${FILESDIR}"/${PV}-gentoo-fb-path.patch
	)

src_prepare() {
	autotools-utils_src_prepare
	eautoreconf
}

src_configure() {
	local myeconfargs=(
		--localstatedir=/var
		$(use_enable pango)
		$(use_enable gdm gdm-transition)
		$(use_enable video_cards_intel libdrm_intel)
		$(use_enable video_cards_nouveau libdrm_nouveau)
		$(use_enable video_cards_radeon libdrm_radeon)
		)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	if use static-libs; then
		mv "${D}/$(get_libdir)"/libply{,-splash-core}.{a,la} \
			"${D}/usr/$(get_libdir)"/ || die 'mv *.{a,la} files failed'
		gen_usr_ldscript libply.so libply-splash-core.so
	else
		einfo "Removing /usr/$(get_libdir)/plymouth/*.la"
		rm "${D}/usr/$(get_libdir)"/plymouth/{*.la,renderers/*.la} \
			|| die 'rm *.la'
	fi

	insinto /usr/share/plymouth
	newins "${DISTDIR}"/gentoo-logo.png bizcom.png || die 'branding failed'
}

pkg_postinst() {
	elog "Follow instructions on"
	elog ""
	elog "  http://dev.gentoo.org/~aidecoe/doc/en/plymouth.xml"
	elog ""
	elog "to set up Plymouth."
}