[gentoo-commits] gentoo-x86 commit in media-libs/libcanberra: ChangeLog libcanberra-0.28-r2.ebuild

[Gilles Dartiguelongue (eva)]

eva         11/05/08 13:52:45

  Modified:             ChangeLog
  Added:                libcanberra-0.28-r2.ebuild
  Log:
  Add support for systemd, bug #366177.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 media-libs/libcanberra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	1 May 2011 16:21:53 -0000	1.67
+++ ChangeLog	8 May 2011 13:52:45 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libcanberra
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.67 2011/05/01 16:21:53 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.68 2011/05/08 13:52:45 eva Exp $
+
+*libcanberra-0.28-r2 (08 May 2011)
+
+  08 May 2011; Gilles Dartiguelongue <eva@g.o>
+  +libcanberra-0.28-r2.ebuild:
+  Add support for systemd, bug #366177.
 
 *libcanberra-0.28-r1 (01 May 2011)
 



1.1                  media-libs/libcanberra/libcanberra-0.28-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/libcanberra-0.28-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/libcanberra-0.28-r2.ebuild?rev=1.1&content-type=text/plain

Index: libcanberra-0.28-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/libcanberra-0.28-r2.ebuild,v 1.1 2011/05/08 13:52:45 eva Exp $

EAPI="4"

inherit gnome2-utils libtool systemd

DESCRIPTION="Portable Sound Event Library"
HOMEPAGE="http://0pointer.de/lennart/projects/libcanberra/"
SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="alsa gstreamer +gtk +gtk3 oss pulseaudio +sound tdb udev"

COMMON_DEPEND="media-libs/libvorbis
	>=sys-devel/libtool-2.2.6b
	alsa? (
		media-libs/alsa-lib
		udev? ( >=sys-fs/udev-160 ) )
	gstreamer? ( >=media-libs/gstreamer-0.10.15 )
	gtk? ( >=x11-libs/gtk+-2.20.0:2
		gnome-base/gconf:2 )
	gtk3? ( x11-libs/gtk+:3
		gnome-base/gconf:2 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
	tdb? ( sys-libs/tdb )
"
RDEPEND="${COMMON_DEPEND}
	sound? ( x11-themes/sound-theme-freedesktop )" # Required for index.theme wrt #323379
DEPEND="${COMMON_DEPEND}
	>=dev-util/pkgconfig-0.17"

REQUIRED_USE="udev? ( alsa )"

src_prepare() {
	# Run elibtoolize for ~x86-fbsd.
	use x86-fbsd && elibtoolize
}

src_configure() {
	econf \
		--docdir=/usr/share/doc/${PF} \
		--disable-dependency-tracking \
		$(use_enable alsa) \
		$(use_enable oss) \
		$(use_enable pulseaudio pulse) \
		$(use_enable gstreamer) \
		$(use_enable gtk) \
		$(use_enable gtk3) \
		$(use_enable tdb) \
		$(use_enable udev) \
		$(systemd_with_unitdir) \
		--disable-lynx \
		--disable-gtk-doc \
		--with-html-dir=/usr/share/doc/${PF}/html
}

src_install() {
	# Disable parallel installation until bug #253862 is solved
	emake -j1 DESTDIR="${D}" install || die

	# Remove useless .la files
	# la files in /usr/lib*/${P}/ are needed
	rm -v "${ED}"/usr/$(get_libdir)/gtk-*/modules/*.la || die
	rm -v "${ED}"/usr/$(get_libdir)/*.la || die
}

pkg_preinst() { gnome2_gconf_savelist; }
pkg_postinst() { gnome2_gconf_install; }