[gentoo-commits] repo/gentoo:master commit in: dev-util/cgdb/

[Joonas Niilola]

commit:     29c378d889d06d2f1631a4e36750bec7fbd2269a
Author:     Jakov Smolic <jakov.smolic <AT> sartura <DOT> hr>
AuthorDate: Sat Aug 15 13:44:15 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sat Sep  5 07:53:46 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29c378d8

dev-util/cgdb: revbump for bugfixes

Closes: https://bugs.gentoo.org/730138
Closes: https://bugs.gentoo.org/682386
Closes: https://bugs.gentoo.org/678006
Closes: https://bugs.gentoo.org/630512
Package-Manager: Portage-2.3.99, Repoman-2.3.23
Signed-off-by: Jakov Smolic <jakov.smolic <AT> sartura.hr>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/cgdb/cgdb-0.7.0-r2.ebuild | 68 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/dev-util/cgdb/cgdb-0.7.0-r2.ebuild b/dev-util/cgdb/cgdb-0.7.0-r2.ebuild
new file mode 100644
index 00000000000..41d85a3805a
--- /dev/null
+++ b/dev-util/cgdb/cgdb-0.7.0-r2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="
+		https://github.com/cgdb/cgdb.git
+		git@××××××.com:cgdb/cgdb.git"
+else
+	SRC_URI="https://github.com/cgdb/cgdb/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+inherit multilib-minimal
+
+DESCRIPTION="A curses front-end for GDB, the GNU debugger"
+HOMEPAGE="http://cgdb.github.io/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0="
+
+BDEPEND="
+	test? (
+		dev-util/dejagnu
+		app-misc/dtach
+	)"
+
+RDEPEND="
+	${DEPEND}
+	sys-devel/gdb"
+
+DOCS=( AUTHORS ChangeLog FAQ INSTALL NEWS README.md )
+
+PATCHES=(
+	# Bugs: #730138, #678006, #630512, #682386
+	"${FILESDIR}/${PN}-test.patch"
+)
+
+src_prepare() {
+	default
+	./autogen.sh || die
+}
+
+multilib_src_test() {
+	# Tests need an interactive shell, #654986
+
+	# real-time output of the log ;-)
+	touch "${T}/dtach-test.log" || die
+	tail -f "${T}/dtach-test.log" &
+	local tail_pid=${!}
+
+	nonfatal dtach -N "${T}/dtach.sock" \
+		bash -c 'emake check &> "${T}"/dtach-test.log; echo ${?} > "${T}"/dtach-test.out'
+
+	kill "${tail_pid}"
+	[[ -f ${T}/dtach-test.out ]] || die "Unable to run tests"
+	[[ $(<"${T}"/dtach-test.out) == 0 ]] || die "Tests failed"
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf
+}