[gentoo-commits] gentoo-x86 commit in games-rpg/manaplus: manaplus-1.3.3.3.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    13/03/04 19:06:57

  Modified:             ChangeLog
  Added:                manaplus-1.3.3.3.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha164/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.2                  games-rpg/manaplus/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-rpg/manaplus/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-rpg/manaplus/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-rpg/manaplus/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-rpg/manaplus/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	4 Feb 2013 18:23:28 -0000	1.1
+++ ChangeLog	4 Mar 2013 19:06:57 -0000	1.2
@@ -1,6 +1,11 @@
 # ChangeLog for games-rpg/manaplus
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-rpg/manaplus/ChangeLog,v 1.1 2013/02/04 18:23:28 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-rpg/manaplus/ChangeLog,v 1.2 2013/03/04 19:06:57 hasufell Exp $
+
+*manaplus-1.3.3.3 (04 Mar 2013)
+
+  04 Mar 2013; Julian Ospald <hasufell@g.o> +manaplus-1.3.3.3.ebuild:
+  version bump
 
 *manaplus-1.3.2.3 (04 Feb 2013)
 



1.1                  games-rpg/manaplus/manaplus-1.3.3.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-rpg/manaplus/manaplus-1.3.3.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-rpg/manaplus/manaplus-1.3.3.3.ebuild?rev=1.1&content-type=text/plain

Index: manaplus-1.3.3.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-rpg/manaplus/manaplus-1.3.3.3.ebuild,v 1.1 2013/03/04 19:06:57 hasufell Exp $

EAPI=5

inherit games

DESCRIPTION="OpenSource 2D MMORPG client for Evol Online and The Mana World"
HOMEPAGE="http://manaplus.evolonline.org"
SRC_URI="http://download.evolonline.org/manaplus/download/${PV}/manaplus-${PV}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls opengl"

RDEPEND="
	>=dev-games/physfs-1.0.0
	dev-libs/libxml2
	media-libs/sdl-mixer[vorbis]
	media-libs/sdl-image[png]
	media-libs/sdl-net
	media-libs/sdl-ttf
	net-misc/curl
	sys-libs/zlib
	media-libs/libpng:0
	media-fonts/dejavu
	>=dev-games/guichan-0.8.1[sdl]
	media-libs/libsdl[X,opengl?,video]
	media-libs/sdl-gfx
	x11-apps/xmessage
	x11-libs/libX11
	x11-misc/xdg-utils
	x11-misc/xsel
	nls? ( virtual/libintl )
	opengl? ( virtual/opengl )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

src_prepare() {
	sed -i \
		-e '/^SUBDIRS/s/fonts//' \
		data/Makefile.in || die

	rm -r src/guichan || die
}

src_configure() {
	egamesconf \
		--without-internalguichan \
		--localedir=/usr/share/locale \
		--disable-manaserv \
		--disable-eathena \
		$(use_with opengl) \
		$(use_enable nls)
}

src_install() {
	default

	dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf "${GAMES_DATADIR}"/${PN}/data/fonts/dejavusans-bold.ttf
	dosym /usr/share/fonts/dejavu/DejaVuSans.ttf "${GAMES_DATADIR}"/${PN}/data/fonts/dejavusans.ttf
	dosym /usr/share/fonts/dejavu/DejaVuSansMono.ttf "${GAMES_DATADIR}"/${PN}/data/fonts/dejavusans-mono.ttf
	insinto "${GAMES_DATADIR}"/${PN}/data

	prepgamesdirs
}