[gentoo-commits] repo/gentoo:master commit in: games-action/xblast/

[Ionen Wolkens]

commit:     e3fcf31b76bf18de67dcb4cc1eb7670e3ca627cc
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 16 21:51:11 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Sep 16 23:14:35 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e3fcf31b

games-action/xblast: EAPI6->8, fix filename, add font dep

Game crashes immediately if font is missing.

Also add a basic .desktop entry.

Closes: https://bugs.gentoo.org/750077
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-action/xblast/xblast-2.10.4-r1.ebuild | 74 -----------------------------
 games-action/xblast/xblast-2.10.4-r2.ebuild | 65 +++++++++++++++++++++++++
 2 files changed, 65 insertions(+), 74 deletions(-)

diff --git a/games-action/xblast/xblast-2.10.4-r1.ebuild b/games-action/xblast/xblast-2.10.4-r1.ebuild
deleted file mode 100644
index 3da27dd600a..00000000000
--- a/games-action/xblast/xblast-2.10.4-r1.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit autotools
-
-# Change these as releases changes
-IMAGES="images-2005-01-06"
-LEVELS="levels-2005-01-06"
-MODELS="models-2005-01-06"
-MUSICS="musics-2005-01-06"
-SOUNDS="sounds"
-
-DESCRIPTION="Bomberman clone w/network support for up to 6 players"
-HOMEPAGE="http://xblast.sourceforge.net/"
-SRC_URI="mirror://sourceforge/xblast/${P}.tar.gz
-	mirror://sourceforge/xblast/${IMAGES}.tar.gz
-	mirror://sourceforge/xblast/${LEVELS}.tar.gz
-	mirror://sourceforge/xblast/${MODELS}.tar.gz
-	mirror://sourceforge/xblast/${MUSICS}.tar.gz
-	mirror://sourceforge/xblast/${SOUNDS}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="
-	media-libs/libpng:0
-	x11-libs/libICE
-	x11-libs/libX11"
-DEPEND="${RDEPEND}
-	x11-libs/libXt"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-gcc-10.patch
-)
-
-src_prepare() {
-	default
-
-	eautoreconf #255857
-}
-
-src_configure() {
-	econf \
-		--with-otherdatadir=/usr/share/${PN} \
-		--enable-sound
-}
-
-src_install() {
-	local IMAGE_INSTALL_DIR="/usr/share/${PN}/image"
-
-	default
-
-	# Images
-	dodir "${IMAGE_INSTALL_DIR}"
-	cp -pPR "${WORKDIR}/${IMAGES}"/* "${D}/${IMAGE_INSTALL_DIR}" || die
-
-	# Levels
-	insinto "/usr/share/${PN}/level"
-	doins "${WORKDIR}/${LEVELS}"/*
-
-	# Models
-	insinto "/usr/share/${PN}/image/sprite"
-	doins "${WORKDIR}/${MODELS}"/*
-
-	# Music and sound
-	insinto "/usr/share/${PN}/sounds"
-	doins "${WORKDIR}/${MUSICS}"/* "${WORKDIR}/${SOUNDS}"/*
-
-	# Cleanup
-	find "${D}" -name Imakefile -exec rm \{\} \;
-}

diff --git a/games-action/xblast/xblast-2.10.4-r2.ebuild b/games-action/xblast/xblast-2.10.4-r2.ebuild
new file mode 100644
index 00000000000..0f7e212495e
--- /dev/null
+++ b/games-action/xblast/xblast-2.10.4-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop
+
+MY_GAMEDATA=(
+	images-2005-01-06:image
+	levels-2005-01-06:level
+	models-2005-01-06:image/sprite
+	musics-2005-01-06:sounds
+	sounds
+)
+
+DESCRIPTION="Bomberman clone with network support for up to 6 players"
+HOMEPAGE="http://xblast.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/xblast/${P}.tar.gz
+	$(printf 'mirror://sourceforge/xblast/%s.tar.gz ' "${MY_GAMEDATA[@]%:*}")"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	x11-libs/libX11
+	media-fonts/font-adobe-100dpi"
+DEPEND="
+	x11-base/xorg-proto
+	x11-libs/libX11
+	x11-libs/libXt"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc-10.patch
+)
+
+src_prepare() {
+	default
+
+	find "${WORKDIR}" -name Imakefile -exec rm {} + || die
+
+	# badly non-utf8 named file that doesn't match xblast.wxs runtime #750077
+	mv "${WORKDIR}"/levels-2005-01-06/reconstruct{?,i}on2.xal || die
+
+	eautoreconf #255857
+}
+
+src_configure() {
+	econf \
+		--enable-sound \
+		--with-otherdatadir="${EPREFIX}"/usr/share/${PN}
+}
+
+src_install() {
+	default
+
+	local data
+	for data in "${MY_GAMEDATA[@]}"; do
+		insinto /usr/share/${PN}/${data#*:}
+		doins -r "${WORKDIR}"/${data%:*}/.
+	done
+
+	make_desktop_entry ${PN} XBlast applications-games
+}