[gentoo-commits] gentoo-x86 commit in dev-util/eric: eric-4.5.17.ebuild eric-5.4.0_rc1.ebuild ChangeLog eric-4.5.16.ebuild

[Davide Pesavento (pesa)]

pesa        13/12/27 01:54:52

  Modified:             ChangeLog
  Added:                eric-4.5.17.ebuild eric-5.4.0_rc1.ebuild
  Removed:              eric-4.5.16.ebuild
  Log:
  Version bumps. Switch to python-single-r1 for 5.4 and raise some dependencies.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.208                dev-util/eric/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?rev=1.208&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?rev=1.208&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?r1=1.207&r2=1.208

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v
retrieving revision 1.207
retrieving revision 1.208
diff -u -r1.207 -r1.208
--- ChangeLog	25 Dec 2013 19:35:34 -0000	1.207
+++ ChangeLog	27 Dec 2013 01:54:52 -0000	1.208
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/eric
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.207 2013/12/25 19:35:34 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.208 2013/12/27 01:54:52 pesa Exp $
+
+*eric-5.4.0_rc1 (27 Dec 2013)
+*eric-4.5.17 (27 Dec 2013)
+
+  27 Dec 2013; Davide Pesavento <pesa@g.o> +eric-4.5.17.ebuild,
+  +eric-5.4.0_rc1.ebuild, -eric-4.5.16.ebuild:
+  Version bumps. Switch to python-single-r1 for 5.4 and raise some dependencies.
 
   25 Dec 2013; Davide Pesavento <pesa@g.o> -eric-4.5.10.ebuild:
   old



1.1                  dev-util/eric/eric-4.5.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-4.5.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-4.5.17.ebuild?rev=1.1&content-type=text/plain

Index: eric-4.5.17.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-4.5.17.ebuild,v 1.1 2013/12/27 01:54:52 pesa Exp $

EAPI=4

PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"
# 2.4 and 2.5 are restricted to avoid conditional dependency on dev-python/simplejson.
RESTRICT_PYTHON_ABIS="2.4 2.5 3.* *-jython 2.7-pypy-*"

PLOCALES="cs de en es fr it ru tr zh_CN"

inherit eutils l10n python

DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
HOMEPAGE="http://eric-ide.python-projects.org/"

SLOT="4"
MY_PV=${PV/_pre/-snapshot-}
MY_P=${PN}${SLOT}-${MY_PV}

BASE_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}"
SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
for L in ${PLOCALES}; do
	SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${PN}${SLOT}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
done
unset L

LICENSE="GPL-3"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="kde spell"

DEPEND="
	>=dev-python/sip-4.12.4
	>=dev-python/PyQt4-4.9.6-r1[X,help,svg,webkit]
	>=dev-python/qscintilla-python-2.3
	kde? ( kde-base/pykde4 )
"
RDEPEND="${DEPEND}
	>=dev-python/chardet-2.0.1
	>=dev-python/coverage-3.0.1
	>=dev-python/pygments-1.3.1
"
PDEPEND="
	spell? ( dev-python/pyenchant )
"

S=${WORKDIR}/${MY_P}

PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")

src_prepare() {
	epatch "${FILESDIR}/eric-4.5-no-interactive.patch"
	use kde || epatch "${FILESDIR}/eric-4.4-no-pykde.patch"

	# Delete internal copies of dev-python/chardet, dev-python/coverage,
	# dev-python/pygments and dev-python/simplejson.
	rm -fr eric/ThirdParty
	rm -fr eric/DebugClients/Python{,3}/coverage
	sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
}

src_install() {
	installation() {
		"$(PYTHON)" install.py \
			-z \
			-b "${EPREFIX}/usr/bin" \
			-i "${T}/images/${PYTHON_ABI}" \
			-d "${EPREFIX}$(python_get_sitedir)" \
			-c
	}
	python_execute_function installation
	python_merge_intermediate_installation_images "${T}/images"

	doicon eric/icons/default/eric.png || die
	make_desktop_entry "eric4 --nosplash" eric4 eric "Development;IDE;Qt"
}

pkg_postinst() {
	python_mod_optimize eric4{,config.py,plugins}

	elog
	elog "If you want to use Eric with mod_python, have a look at"
	elog "\"${EROOT}$(python_get_sitedir -b -f)/eric4/patch_modpython.py\"."
	elog
	elog "The following packages will give Eric extended functionality:"
	elog "  dev-python/pylint"
	elog "  dev-python/pysvn"
	elog
	elog "This version has a plugin interface with plugin-autofetch from"
	elog "the application itself. You may want to check those as well."
	elog
}

pkg_postrm() {
	python_mod_cleanup eric4{,config.py,plugins}
}



1.1                  dev-util/eric/eric-5.4.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-5.4.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-5.4.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: eric-5.4.0_rc1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-5.4.0_rc1.ebuild,v 1.1 2013/12/27 01:54:52 pesa Exp $

EAPI=5

PYTHON_COMPAT=( python3_2 )
PYTHON_REQ_USE="sqlite,xml"
PLOCALES="cs de en es fr it ru tr zh_CN"

inherit eutils l10n python-single-r1

DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
HOMEPAGE="http://eric-ide.python-projects.org/"

SLOT="5"
MY_PV=${PV/_rc/-RC}
MY_P=${PN}${SLOT}-${MY_PV}

BASE_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${MY_PV}"
SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
for L in ${PLOCALES}; do
	SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${PN}${SLOT}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
done
unset L

LICENSE="GPL-3"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="spell"

DEPEND="
	${PYTHON_DEPS}
	>=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
	>=dev-python/PyQt4-4.10[${PYTHON_USEDEP},X,help,sql,svg,webkit]
	>=dev-python/qscintilla-python-2.7.1[${PYTHON_USEDEP}]
"
RDEPEND="${DEPEND}
	>=dev-python/chardet-2.0.1[${PYTHON_USEDEP}]
	>=dev-python/coverage-3.2[${PYTHON_USEDEP}]
	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
"
PDEPEND="
	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )
"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

S=${WORKDIR}/${MY_P}

src_prepare() {
	# Avoid file collisions between different slots of Eric.
	sed -i -e 's/^Icon=eric$/&5/' eric/eric5.desktop || die
	sed -i -e 's/\([^[:alnum:]]\)eric\.png\([^[:alnum:]]\)/\1eric5.png\2/' \
		$(grep -lr 'eric\.png' .) || die
	mv eric/icons/default/eric{,5}.png || die
	mv eric/pixmaps/eric{,5}.png || die
	rm -f eric/APIs/Python/zope-*.api
	rm -f eric/APIs/Ruby/Ruby-*.api

	# Delete internal copies of dev-python/chardet,
	# dev-python/coverage and dev-python/pygments.
	rm -fr eric/ThirdParty/{CharDet,Pygments}
	rm -fr eric/DebugClients/Python{,3}/coverage
	sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die

	# Fix desktop files (bug 458092).
	sed -i -e '/^Categories=/s:Python:X-&:' eric/eric5{,_webbrowser}.desktop || die
}

src_install() {
	"${PYTHON}" install.py \
		-b "${EPREFIX}/usr/bin" \
		-d "$(python_get_sitedir)" \
		-i "${D}" \
		-c \
		-z \
		|| die

	python_optimize

	doicon eric/icons/default/eric5.png
	dodoc changelog THANKS
}

pkg_postinst() {
	elog "The following packages will give Eric extended functionality:"
	elog "  dev-python/cx_Freeze"
	elog "  dev-python/pylint"
	elog "  dev-python/pysvn"
	elog "  dev-vcs/mercurial"
	elog
	elog "This version has a plugin interface with plugin-autofetch from"
	elog "the application itself. You may want to check those as well."
}