[gentoo-commits] gentoo-x86 commit in sys-libs/ss: ChangeLog ss-1.40.3.ebuild

[Mike Frysinger (vapier)]

vapier      07/12/08 21:13:04

  Modified:             ChangeLog
  Added:                ss-1.40.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.4_rc4)

Revision  Changes    Path
1.36                 sys-libs/ss/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	26 Nov 2007 03:20:38 -0000	1.35
+++ ChangeLog	8 Dec 2007 21:13:04 -0000	1.36
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/ss
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v 1.35 2007/11/26 03:20:38 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v 1.36 2007/12/08 21:13:04 vapier Exp $
+
+*ss-1.40.3 (08 Dec 2007)
+
+  08 Dec 2007; Mike Frysinger <vapier@g.o> +ss-1.40.3.ebuild:
+  Version bump.
 
   26 Nov 2007; Jeroen Roovers <jer@g.o> ss-1.40.2.ebuild:
   Stable for HPPA (bug #200192).



1.1                  sys-libs/ss/ss-1.40.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ss-1.40.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ss-1.40.3.ebuild?rev=1.1&content-type=text/plain

Index: ss-1.40.3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ss-1.40.3.ebuild,v 1.1 2007/12/08 21:13:04 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="Subsystem command parsing library"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/e2fsprogs-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="~sys-libs/com_err-${PV}"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/e2fsprogs-${PV}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.39-makefile.patch
}

src_compile() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true

	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	econf \
		--enable-${libtype}-shlibs \
		--with-ldopts="${LDFLAGS}" \
		$(use_enable nls) \
		|| die
	emake -C lib/ss COMPILE_ET=compile_et || die "make ss failed"
}

src_test() {
	make -C lib/ss check || die "make check failed"
}

src_install() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true

	dodir /usr/share/man/man1
	make -C lib/ss DESTDIR="${D}" install || die

	# Move shared libraries to /lib/, install static libraries to /usr/lib/,
	# and install linker scripts to /usr/lib/.
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)/ || die "move .so"
	dolib.a lib/libss.a || die "dolib.a"
	gen_usr_ldscript libss.so
}



-- 
gentoo-commits@g.o mailing list