[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     96fb89f4120ec19ac979fee02ef8b21b99bb5773
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 29 03:22:47 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jul 29 03:24:41 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=96fb89f4

sys-kernel/gentoo-kernel-bin: bump to 5.13.6-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.13.6-r1.ebuild             | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index c8e4002e423..b23411da4ec 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -37,6 +37,7 @@ DIST gentoo-kernel-5.13.5-1.amd64.xpak 67289943 BLAKE2B 4a176cb85c9a62555ffe8ce6
 DIST gentoo-kernel-5.13.5-1.arm64.xpak 62750794 BLAKE2B 98c1fb2327eec70004e4e18f62f9e85809c136e13780f0ab7e96fd627e0d42029d8985cb10ce6afd1dd69ab2fbaf7dd8a2c18b119750fd6d870b7ee681e3bd6c SHA512 737644e56624799aa1fa93361c78939481306805862d1ff84001844528728df823daf6c521bf633745d0d0ff4d398851605a2f81a0aff56165ee33f7b8107feb
 DIST gentoo-kernel-5.13.5-1.x86.xpak 58492372 BLAKE2B 21ace06930af832e3465dfa5ecf6597639b2376d749f96f432a3ef82fe001a393afb3659b29c54d10319b73fe3223273f7a6c9fbad3b1343b9c6f317998c7b48 SHA512 a3262bf06f03ed74b4e65daebf00ca9fa7778fe79c3418f2e6e34eb3134fb466b4f5797dc3d884d869ae7358af539a1b42a7b39b9268db38289e0ba3dc924550
 DIST gentoo-kernel-5.13.6-1.amd64.xpak 67333225 BLAKE2B 8ac29fcac29fc999afb27475706feb84cb45c29226112d20dbc4dc10eee76e3b5e6be3c0c9eaf6702e582d20f2171b597a62723a8b65d9d55c67d49d12605b2d SHA512 14210da32d70e6a8c3efe25dd1d007fd049050c4599b65ded8dec9173ac271c9d6e668d53e9c7789414a74d9de0164605e57244fbdf5ffe39e4a9818edb4d52a
+DIST gentoo-kernel-5.13.6-1.arm64.xpak 62701469 BLAKE2B 65be6a649fbb7a64e9bb66aecf17d70c4b0f55ffdb39faf28602b366ea74d500b5f497a16b2056339aef553135de17660606b950c2064528ad5d27ccb5a6d178 SHA512 018b4b7d0283cdce9b0fa154ff9ba0162f5d82a37a272be187949522124c1d1c856ddd264b315392f394362ce42dcf71d36b83981dd39db9fd67fc0d8d60ee46
 DIST gentoo-kernel-5.13.6-1.x86.xpak 58503030 BLAKE2B 155b0e3dbb55457f6f9d2eb4888ac4a31e31ee83374761c115773b7f4068940b3783ec6de76544f312486a7b678545060d39a5876a8499e9b5ffc359969873e2 SHA512 2002d1ffa8ff9ab7182db9e99be7afc61657060649479238bd1764ef20d189f3ad9bb22df63c41aad2d7a742a48c437965f41dfedee613ef33fa9d5e8ac34330
 DIST gentoo-kernel-5.4.134-1.amd64.xpak 61349154 BLAKE2B c7627b1a8ad85b22450ae1b47a26f9144707f8a2173b01859ea1d876cf4d96e9fcc27be439e6c0239d7494795cc62fa931ecc71be84f9f898ec017a79d82dcf9 SHA512 d4c6613ed069a0ec2dbb5f5bb317abe952309f6ba6fbb163cbf1392478b1756dd129e51665b3b4e9c939395f5cdbc553003d7f0201098f959be9d29233a48cc9
 DIST gentoo-kernel-5.4.134-1.arm64.xpak 56052116 BLAKE2B 6a901fb6a639470145c8b58e435cfe4a380ebd402397ca34eace732936fda8e38a8e92e0f49d747e6f1ae8fb5410960e236ea2cc22dbc7f25ac833275b9b6fea SHA512 216287843b7d1e740afa3c88376e5d5ae99d88882b6669c753fdd341d7f9cd84ee8cbf28fb08f6101b9a9263ce20c6ddeeececf078c7387e571eac53baa52204

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.6-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.6-r1.ebuild
new file mode 100644
index 00000000000..2f16601a52d
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.6-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}