[gentoo-commits] repo/gentoo:master commit in: dev-python/wheel/

[Michał Górny]

commit:     11e691ee9b5d9b8b56c1289163cefb7f1fcfa534
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 26 12:12:23 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan 26 12:21:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=11e691ee

dev-python/wheel: Use flit to ease bootstrap

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/wheel/wheel-0.37.1-r1.ebuild | 61 +++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/dev-python/wheel/wheel-0.37.1-r1.ebuild b/dev-python/wheel/wheel-0.37.1-r1.ebuild
new file mode 100644
index 000000000000..a271177181e7
--- /dev/null
+++ b/dev-python/wheel/wheel-0.37.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="A built-package format for Python"
+HOMEPAGE="https://pypi.org/project/wheel/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+SRC_URI="https://github.com/pypa/wheel/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed \
+		-e 's:--cov --cov-config=setup.cfg::g' \
+		-i setup.cfg || die
+
+	# unbundle packaging
+	rm -r src/wheel/vendored || die
+	sed -i -e 's:\.vendored\.::' src/wheel/*.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	[[ -e pyproject.toml ]] &&
+		die "Upstream added pyproject.toml, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "wheel"
+		description = "A built-package format for Python"
+		dynamic = ["version"]
+
+		[project.scripts]
+		wheel = "wheel.cli:main"
+
+		[project.entry-points."distutils.commands"]
+		bdist_wheel = "wheel.bdist_wheel:bdist_wheel"
+	EOF
+}