[gentoo-commits] gentoo-x86 commit in media-libs/libraw: ChangeLog libraw-0.13.6.ebuild

[Tim Harder (radhermit)]

radhermit    11/07/04 08:29:22

  Modified:             ChangeLog
  Added:                libraw-0.13.6.ebuild
  Log:
  Version bump. Add static-libs USE flag.
  
  (Portage version: 2.2.0_alpha41/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  media-libs/libraw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	23 May 2011 21:55:55 -0000	1.5
+++ ChangeLog	4 Jul 2011 08:29:22 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libraw
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.5 2011/05/23 21:55:55 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.6 2011/07/04 08:29:22 radhermit Exp $
+
+*libraw-0.13.6 (04 Jul 2011)
+
+  04 Jul 2011; Tim Harder <radhermit@g.o> +libraw-0.13.6.ebuild,
+  +files/libraw-0.13.6-makefile.patch:
+  Version bump. Add static-libs USE flag.
 
 *libraw-0.13.5 (23 May 2011)
 



1.1                  media-libs/libraw/libraw-0.13.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/libraw-0.13.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/libraw-0.13.6.ebuild?rev=1.1&content-type=text/plain

Index: libraw-0.13.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/libraw-0.13.6.ebuild,v 1.1 2011/07/04 08:29:22 radhermit Exp $

EAPI="4"

inherit eutils autotools

MY_P="LibRaw-${PV}"
DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
HOMEPAGE="http://www.libraw.org/"
SRC_URI="http://www.libraw.org/data/${MY_P}.tar.gz
	demosaic? ( https://github.com/LibRaw/LibRaw-demosaic-pack-GPL2/tarball/${PV} -> LibRaw-demosaic-pack-GPL2-${PV}.tar.gz
		https://github.com/LibRaw/LibRaw-demosaic-pack-GPL3/tarball/${PV} -> LibRaw-demosaic-pack-GPL3-${PV}.tar.gz )"

# Libraw also has it's own license, which is a pdf file and
# can be obtained from here:
# http://www.libraw.org/data/LICENSE.LibRaw.pdf
LICENSE="LGPL-2.1 CDDL GPL-2 GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="demosaic examples +lcms +openmp static-libs"

DEPEND="lcms? ( media-libs/lcms:2 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

DOCS=( Changelog.txt README )

src_unpack() {
	unpack ${A}
	if use demosaic ; then
		mv *LibRaw-demosaic*GPL2* LibRaw-demosaic-pack-GPL2-${PV}
		mv *LibRaw-demosaic*GPL3* LibRaw-demosaic-pack-GPL3-${PV}
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.13.4-docs.patch \
		"${FILESDIR}"/${P}-makefile.patch
	eautomake
}

src_configure() {
	econf \
		$(use_enable demosaic demosaic-pack-gpl2) \
		$(use_enable demosaic demosaic-pack-gpl3) \
		$(use_enable examples) \
		$(use_enable lcms) \
		$(use_enable openmp) \
		$(use_enable static-libs static)
}

src_install() {
	default

	# Remove useless .la files
	find "${D}" -name '*.la' -exec rm -f {} +
}