[gentoo-commits] gentoo-x86 commit in net-analyzer/net-snmp: net-snmp-5.7.2.1.ebuild ChangeLog net-snmp-5.7.2.ebuild net-snmp-5.7.2_rc1.ebuild

[Jeroen Roovers (jer)]

jer         14/03/01 19:51:59

  Modified:             ChangeLog
  Added:                net-snmp-5.7.2.1.ebuild
  Removed:              net-snmp-5.7.2.ebuild net-snmp-5.7.2_rc1.ebuild
  Log:
  Version bump (bug #502968).
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.262                net-analyzer/net-snmp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/net-snmp/ChangeLog?rev=1.262&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/net-snmp/ChangeLog?rev=1.262&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/net-snmp/ChangeLog?r1=1.261&r2=1.262

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/net-snmp/ChangeLog,v
retrieving revision 1.261
retrieving revision 1.262
diff -u -r1.261 -r1.262
--- ChangeLog	18 Jan 2014 20:04:37 -0000	1.261
+++ ChangeLog	1 Mar 2014 19:51:59 -0000	1.262
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/net-snmp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/net-snmp/ChangeLog,v 1.261 2014/01/18 20:04:37 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/net-snmp/ChangeLog,v 1.262 2014/03/01 19:51:59 jer Exp $
+
+*net-snmp-5.7.2.1 (01 Mar 2014)
+
+  01 Mar 2014; Jeroen Roovers <jer@g.o> -net-snmp-5.7.2_rc1.ebuild,
+  -net-snmp-5.7.2.ebuild, +net-snmp-5.7.2.1.ebuild:
+  Version bump (bug #502968).
 
   18 Jan 2014; Agostino Sarubbo <ago@g.o> net-snmp-5.7.2-r1.ebuild:
   Stable for alpha, wrt bug #494574



1.1                  net-analyzer/net-snmp/net-snmp-5.7.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/net-snmp/net-snmp-5.7.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/net-snmp/net-snmp-5.7.2.1.ebuild?rev=1.1&content-type=text/plain

Index: net-snmp-5.7.2.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/net-snmp/net-snmp-5.7.2.1.ebuild,v 1.1 2014/03/01 19:51:59 jer Exp $

EAPI=5
PYTHON_COMPAT=( python2_{6,7} )
DISTUTILS_SINGLE_IMPL=yesplz
DISTUTILS_OPTIONAL=yesplz
WANT_AUTOMAKE=none
PATCHSET=1

inherit autotools distutils-r1 eutils perl-module systemd

DESCRIPTION="Software for generating and retrieving SNMP data"
HOMEPAGE="http://net-snmp.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~jer/${P}.tar.gz
	http://dev.gentoo.org/~flameeyes/${PN}/${PN}-5.7.2-patches-${PATCHSET}.tar.xz"

# GPL-2 for the init scripts
LICENSE="HPND BSD GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="bzip2 doc elf ipv6 mfd-rewrites minimal perl python rpm selinux ssl tcpd X zlib lm_sensors ucd-compat pci netlink mysql"

COMMON="ssl? ( >=dev-libs/openssl-0.9.6d )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	rpm? (
		app-arch/rpm
		dev-libs/popt
	)
	bzip2? ( app-arch/bzip2 )
	zlib? ( >=sys-libs/zlib-1.1.4 )
	elf? ( dev-libs/elfutils )
	python? ( dev-python/setuptools ${PYTHON_DEPS} )
	pci? ( sys-apps/pciutils )
	lm_sensors? ( sys-apps/lm_sensors )
	netlink? ( dev-libs/libnl:1.1 )
	mysql? ( virtual/mysql )"

RDEPEND="${COMMON}
	perl? (
		X? ( dev-perl/perl-tk )
		!minimal? ( dev-perl/TermReadKey )
	)
	selinux? ( sec-policy/selinux-snmp )
"

# Dependency on autoconf due to bug #225893
DEPEND="${COMMON}
	>=sys-apps/sed-4
	doc? ( app-doc/doxygen )"

REQUIRED_USE="rpm? ( bzip2 zlib )"

RESTRICT=test

src_prepare() {
	# snmpconf generates config files with proper selinux context
	use selinux && epatch "${FILESDIR}"/${PN}-5.1.2-snmpconf-selinux.patch

	epatch "${WORKDIR}"/patches/*.patch
	eautoconf
}

src_configure() {
	# keep this in the same line, configure.ac arguments are passed down to config.h
	local mibs="host ucd-snmp/dlmod ucd-snmp/diskio ucd-snmp/extensible mibII/mta_sendmail smux"
	use lm_sensors && mibs="${mibs} ucd-snmp/lmsensorsMib"

	econf \
		$(use_enable !ssl internal-md5) \
		$(use_enable ipv6) \
		$(use_enable mfd-rewrites) \
		$(use_enable perl embedded-perl) \
		$(use_enable ucd-compat ucd-snmp-compatibility) \
		$(use_with bzip2) \
		$(use_with elf) \
		$(use_with mysql) \
		$(use_with netlink nl) \
		$(use_with pci) \
		$(use_with perl perl-modules INSTALLDIRS=vendor) \
		$(use_with python python-modules) \
		$(use_with rpm) \
		$(use_with ssl openssl) \
		$(use_with tcpd libwrap) \
		$(use_with zlib) \
		--enable-shared --disable-static \
		--with-default-snmp-version="3" \
		--with-install-prefix="${D}" \
		--with-ldflags="${LDFLAGS}" \
		--with-logfile="/var/log/net-snmpd.log" \
		--with-mib-modules="${mibs}" \
		--with-persistent-directory="/var/lib/net-snmp" \
		--with-sys-contact="root@Unknown" \
		--with-sys-location="Unknown"
}

src_compile() {
	emake \
		OTHERLDFLAGS="${LDFLAGS}" \
		sedscript all

	use doc && emake docsdox
}

src_install () {
	# bug #317965
	emake -j1 DESTDIR="${D}" install

	if use perl ; then
		fixlocalpod
		use X || rm -f "${D}"/usr/bin/tkmib
	else
		rm -f "${D}"/usr/bin/mib2c "${D}"/usr/bin/snmpcheck "${D}"/usr/bin/tkmib
	fi

	dodoc AGENT.txt ChangeLog FAQ INSTALL NEWS PORTING README* TODO
	newdoc EXAMPLE.conf.def EXAMPLE.conf

	use doc && dohtml docs/html/*

	keepdir /var/lib/net-snmp

	newinitd "${FILESDIR}"/snmpd.init.2 snmpd
	newconfd "${FILESDIR}"/snmpd.conf snmpd

	newinitd "${FILESDIR}"/snmptrapd.init.2 snmptrapd
	newconfd "${FILESDIR}"/snmptrapd.conf snmptrapd

	systemd_dounit "${FILESDIR}"/snmpd.service
	systemd_dounit "${FILESDIR}"/snmptrapd.service

	insinto /etc/snmp
	newins "${S}"/EXAMPLE.conf snmpd.conf.example

	# Remove everything not required for an agent.
	# Keep only the snmpd, snmptrapd, MIBs, headers and libraries.
	if use minimal; then
		rm -rf \
			"${D}"/usr/bin/{encode_keychange,snmp{get,getnext,set,usm,walk,bulkwalk,table,trap,bulkget,translate,status,delta,test,df,vacm,netstat,inform,check,conf},fixproc,traptoemail} \
			"${D}"/usr/share/snmp/snmpconf-data \
			"${D}"/usr/share/snmp/*.conf \
			"${D}"/**/*.pl
	fi
}