[gentoo-commits] repo/gentoo:master commit in: sys-cluster/galera/

[Brian Evans]

commit:     3c7dc41d91e8fe5492ada9937971218687064bf7
Author:     Brian Evans <grknight <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 18 15:39:53 2019 +0000
Commit:     Brian Evans <grknight <AT> gentoo <DOT> org>
CommitDate: Mon Nov 18 15:40:31 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c7dc41d

sys-cluster/galera: Revbump dropping user eclass for new service

New service script uses the standard 'nobody' user which is in baselayout
This is used by other distros by default

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Brian Evans <grknight <AT> gentoo.org>

 sys-cluster/galera/galera-25.3.28-r1.ebuild | 81 +++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/sys-cluster/galera/galera-25.3.28-r1.ebuild b/sys-cluster/galera/galera-25.3.28-r1.ebuild
new file mode 100644
index 00000000000..adcb8849262
--- /dev/null
+++ b/sys-cluster/galera/galera-25.3.28-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit python-any-r1 scons-utils toolchain-funcs flag-o-matic
+
+DESCRIPTION="Synchronous multi-master replication engine that provides the wsrep API"
+HOMEPAGE="http://galeracluster.com"
+SRC_URI="http://nyc2.mirrors.digitalocean.com/mariadb/mariadb-10.3.20/${P}/src/${P}.tar.gz"
+LICENSE="GPL-2 BSD"
+
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="cpu_flags_x86_sse4_2 garbd test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-libs/openssl:0=
+	>=dev-libs/boost-1.41:0=
+	"
+BDEPEND=">=sys-devel/gcc-4.4"
+DEPEND="${BDEPEND}
+	${CDEPEND}
+	dev-libs/check
+	>=dev-cpp/asio-1.10.1[ssl]
+	<dev-cpp/asio-1.12.0
+	"
+#Run time only
+RDEPEND="${CDEPEND}"
+
+# Respect {C,LD}FLAGS.
+PATCHES=( "${FILESDIR}/galera-4.1-strip-extra-cflags.patch" )
+
+src_prepare() {
+	default
+
+	# Remove bundled dev-cpp/asio
+	rm -r "${S}/asio" || die
+
+	#Remove optional garbd daemon
+	if ! use garbd ; then
+		rm -r "${S}/garb" || die
+	fi
+}
+
+src_configure() {
+	tc-export CC CXX
+	# Uses hardware specific code that seems to depend on SSE4.2
+	if use cpu_flags_x86_sse4_2 ; then
+		append-cflags -msse4.2
+	else
+		append-cflags -DCRC32C_NO_HARDWARE
+	fi
+	# strict_build_flags=0 disables -Werror, -pedantic, -Weffc++,
+	# and -Wold-style-cast
+	MYSCONS=(
+		tests=$(usex test 1 0)
+		strict_build_flags=0
+		system_asio=1
+	)
+}
+
+src_compile() {
+	escons --warn=no-missing-sconscript "${MYSCONS[@]}"
+}
+
+src_install() {
+	dodoc scripts/packages/README scripts/packages/README-MySQL
+	if use garbd ; then
+		dobin garb/garbd
+		newconfd "${FILESDIR}/garb.cnf" garbd
+		newinitd "${FILESDIR}/garb.init" garbd
+		doman man/garbd.8
+	fi
+	exeinto /usr/$(get_libdir)/${PN}
+	doexe libgalera_smm.so
+}