[gentoo-commits] repo/gentoo:master commit in: media-gfx/inkscape/

[Mikle Kolyada]

commit:     dc819f47d4ca0e93da452194756ef15c240fb639
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 23 19:15:36 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Thu Apr 23 19:16:23 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dc819f47

media-gfx/inkscape: Version bump (v1.0_rc1)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 media-gfx/inkscape/Manifest                |   1 +
 media-gfx/inkscape/inkscape-1.0_rc1.ebuild | 160 +++++++++++++++++++++++++++++
 2 files changed, 161 insertions(+)

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index e36ab94e6b0..0ac112b1794 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -1,2 +1,3 @@
 DIST inkscape-0.92.4.tar.bz2 31929728 BLAKE2B 892bf4ed913019b27a9b8897e3ae32c44152163ded0eb345d59915ffdc9818d29f210de3294ef1b05601141185b5e3b10779778551b860f31e7df5c659492c77 SHA512 b9034605a79cd8aea808edf42e284819951ae1ea67778f0922f4c10224e94aca6c844acbc2294625773f0a7047d4e32ccdada876238a792a2c17db172c88e120
+DIST inkscape-1.0_rc1.tar.xz 31984596 BLAKE2B 7e4a3618522c7bc9bedba8bb2a846e1cbf40e23868f04548e67fa41b9f8f1e8f696af386c0698a43ae6f7033937e1a3d4e772518162f712468b614a5b4d3b4ad SHA512 13e14a6dad1e89e6edf7c0197c43506d127b2e5136a2d8d931ad5ea0671b65b3feed5baf2f631b1a4b8095f285c19ffe5170904c9ce5e3e484d00ca2f0800b89
 DIST inkscape-1.0beta2_2019-12-03_2b71d25d45.tar.xz 39508392 BLAKE2B fd48f22439d1182aff1db5afd74870a6c1d291afb310fc9fa5036fa3c2547ead8c17f6cd67f77a56f655c56af8ffaa7a349b17166c7b18ef3ddf234aa6e57805 SHA512 029508d4867ac0890b2c9c4d274408f849a17e8a7978853df38543d94e7c08d33546a8a40fbcd940da1ba847f11e37ff2bafa285174b65d45ee5de59e907e78f

diff --git a/media-gfx/inkscape/inkscape-1.0_rc1.ebuild b/media-gfx/inkscape/inkscape-1.0_rc1.ebuild
new file mode 100644
index 00000000000..e6249b176dd
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-1.0_rc1.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_REQ_USE="xml"
+
+RELEASE_SUFFIX="1.0rc1_2020-04-09_09960d6f05"
+
+inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
+
+DESCRIPTION="SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/"
+SRC_URI="https://dev.gentoo.org/~zlogene/distfiles/${CATEGORY}/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="cdr dbus dia exif graphicsmagick imagemagick inkjar jemalloc jpeg lcms nls
+openmp postscript spell static-libs svg2 visio wpg"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/poppler-0.57.0:=[cairo]
+	>=dev-cpp/cairomm-1.12
+	>=dev-cpp/glibmm-2.54.1
+	dev-cpp/gtkmm:3.0
+	>=dev-cpp/pangomm-2.40
+	>=dev-libs/boehm-gc-7.1:=
+	dev-libs/double-conversion:=
+	>=dev-libs/glib-2.41
+	>=dev-libs/libsigc++-2.8
+	>=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.1.25
+	dev-libs/gdl:3
+	dev-libs/popt
+	media-gfx/potrace
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/libpng:0=
+	net-libs/libsoup
+	sci-libs/gsl:=
+	x11-libs/libX11
+	>=x11-libs/pango-1.37.2
+	x11-libs/gtk+:3
+	$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_MULTI_USEDEP}]
+		media-gfx/scour[${PYTHON_MULTI_USEDEP}]
+	')
+	cdr? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libcdr
+	)
+	dbus? ( dev-libs/dbus-glib )
+	exif? ( media-libs/libexif )
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
+		graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
+	)
+	jemalloc? ( dev-libs/jemalloc )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	spell? (
+		app-text/aspell
+		app-text/gtkspell:3
+	)
+	visio? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libvisio
+	)
+	wpg? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+"
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_MULTI_USEDEP}]
+	')
+	dia? ( app-office/dia )
+	postscript? ( app-text/ghostscript-gpl )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.65
+"
+
+RESTRICT="test"
+
+S="${WORKDIR}"/${PN}-${RELEASE_SUFFIX}
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+	sed -i "/install.*COPYING/d" CMakeScripts/ConfigCPack.cmake || die
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		# -DWITH_LPETOOL   # Compile with LPE Tool and experimental LPEs enabled
+		-DENABLE_POPPLER=ON
+		-DENABLE_POPPLER_CAIRO=ON
+		-DWITH_PROFILING=OFF
+		-DWITH_LIBCDR=$(usex cdr)
+		-DWITH_DBUS=$(usex dbus)
+		-DWITH_IMAGE_MAGICK=$(usex imagemagick $(usex !graphicsmagick)) # requires ImageMagick 6, only IM must be enabled
+		-DWITH_GRAPHICS_MAGICK=$(usex graphicsmagick $(usex imagemagick)) # both must be enabled to use GraphicsMagick
+		-DWITH_JEMALLOC=$(usex jemalloc)
+		-DENABLE_LCMS=$(usex lcms)
+		-DWITH_OPENMP=$(usex openmp)
+		-DBUILD_SHARED_LIBS=$(usex !static-libs)
+		-DWITH_SVG2=$(usex svg2)
+		-DWITH_LIBVISIO=$(usex visio)
+		-DWITH_LIBWPG=$(usex wpg)
+	)
+	# We should also have,
+	#
+	#   -DWITH_NLS=$(usex nls)
+	#
+	# in this list, but it's broken upstream at the moment:
+	#
+	#  * https://bugs.gentoo.org/699658
+	#  * https://gitlab.com/inkscape/inkscape/issues/168
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	# No extensions are present in beta1
+	local extdir="${ED}"/usr/share/${PN}/extensions
+
+	if [[ -e "${extdir}" ]] && [[ -n $(find "${extdir}" -mindepth 1) ]]; then
+		python_optimize "${ED}"/usr/share/${PN}/extensions
+	fi
+}