[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-hdaps-applet: gnome-hdaps-applet-20081204.ebuild metadata.xml ChangeLog

[Michael Weber (xmw)]

xmw         10/08/24 15:14:12

  Added:                gnome-hdaps-applet-20081204.ebuild metadata.xml
                        ChangeLog
  Log:
  Initial import for gnome-hdaps-applet
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  gnome-extra/gnome-hdaps-applet/gnome-hdaps-applet-20081204.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-hdaps-applet/gnome-hdaps-applet-20081204.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-hdaps-applet/gnome-hdaps-applet-20081204.ebuild?rev=1.1&content-type=text/plain

Index: gnome-hdaps-applet-20081204.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-hdaps-applet/gnome-hdaps-applet-20081204.ebuild,v 1.1 2010/08/24 15:14:12 xmw Exp $

EAPI=2

ETYPE=gcc-library
inherit eutils multilib toolchain-funcs

DESCRIPTION="Visualization of the Hard Disc Active Protection System State as Gnome applet"
HOMEPAGE="http://www.zen24593.zen.co.uk/hdaps/"
SRC_URI="http://www.zen24593.zen.co.uk/hdaps/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

COMMON_DEPEND="gnome-base/gnome-panel
	x11-libs/gtk+:2"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"
RDEPEND="${COMMON_DEPEND}
	app-laptop/hdapsd"

S=${WORKDIR}

src_prepare() {
	epatch "${FILESDIR}"/${P}-include-and-unused.patch
}

src_compile() {
	$(tc-getCC) -c -Wall ${CFLAGS} \
		$($(tc-getPKG_CONFIG) --cflags gtk+-2.0) \
		$($(tc-getPKG_CONFIG) --cflags libpanelapplet-2.0) \
		-o ${PN}.o ${PN}.c || die
	$(tc-getCC) -Wall ${LDFLAGS} -Wl,--as-needed \
		-o ${PN} ${PN}.o \
		$($(tc-getPKG_CONFIG) --libs-only-L gtk+-2.0) \
		$($(tc-getPKG_CONFIG) --libs-only-L libpanelapplet-2.0) \
		-lgtk-x11-2.0 -lpanel-applet-2 || die
}

src_install() {
	dobin ${PN} || die
	insinto /usr/share/pixmaps/${PN}
	doins hdaps-*.png || die
	insinto /usr/$(get_libdir)/bonobo/servers
	doins GNOME_HDAPS_StatusApplet.server || die
}



1.1                  gnome-extra/gnome-hdaps-applet/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-hdaps-applet/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-hdaps-applet/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
<email>xmw@g.o</email>
<name>Michael Weber (xmw)</name>
</maintainer>
</pkgmetadata>




1.1                  gnome-extra/gnome-hdaps-applet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-hdaps-applet/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-hdaps-applet/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for gnome-extra/gnome-hdaps-applet
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-hdaps-applet/ChangeLog,v 1.1 2010/08/24 15:14:12 xmw Exp $

*gnome-hdaps-applet-20081204 (24 Aug 2010)

  24 Aug 2010; Michael Weber (xmw) <xmw@g.o>
  +gnome-hdaps-applet-20081204.ebuild,
  +files/gnome-hdaps-applet-20081204-include-and-unused.patch,
  +metadata.xml:
  Initial commit for gnome-hdaps-applet. Fixes bug #272212.